Incrémentation automatique d'un tableau

Bonjour,

Je veux créer un fichier qui permettrait d'évaluer la durée d'une randonnée à partir de plusieurs points définis par la distance et l'altitude correspondante.

J'ai toutes les bases de calcul, mais j'aimerai faire une présentation d'acquisition simple.

je veux incrémenter automatiquement un tableau de 2 colonnes à partir de deux cellules d'acquisition ( distance , altitude).

Première série d'acquisition ,cellule A1 (distance point 1), stockée dans le tableau colonne 1 ligne 1, deuxième acquisition cellule B1, (altitude point 1), stockée dans le tableau colonne 2 ligne 1.

Deuxième série d'acquisition cellule A1 (distance point 2) stockée dans le tableau colonne 1 ligne 2, deuxième acquisition cellule B1 (altitude point 2) stockée dans le tableau colonne 2 ligne 2.

Et ainsi de suite.

Merci pour votre aide.

Bonjour,

Je ne suis pas sûr de bien comprendre !

Tu veux incrémenter dans une cellule par pas de un une valeur issue de ton tableau ?

Si c'est le cas, tu peux utiliser la fonction Indirect() en utilisant par exemple un bouton toupie issu de la barre Formulaire auquel tu vas lier une cellule.

Avec la formule suivante : =INDIRECT("A"&D1) c'est la cellule D1 qui est liée au bouton et Indirect() retourne la valeur de la cellule en colonne A et ligne = à la valeur du bouton et tu fais de même pour la colonne si les valeurs sont paires !

Je me suis mal expliqué.

Je dois stocker dans un tableau pour les traiter, deux données qui sont liées (distance, altitude)

Pour ne pas saisir les données ligne par ligne dans le tableau ( deux colonnes, une colonne distance, une colonne altitude), je voudrai stocker mes données à partir de deux cellules d'acquisition, une pour la distance et l'autre pour l'altitude.

Les valeurs saisies seraient automatiquement stockées dans le tableau.

Première série de saisies, stockées dans le tableau ligne 1, deuxième saisie de données, saisies dans les mêmes cellules d'acquisition stockées automatiquement dans le tableau ligne 2 et etc.

Merci pour ton aide.

Bonjour,

A mettre dans le module de la feuille. Les deux cellules de saisies sont D1 et E1, les valeurs sont ensuite inscrites dans les colonnes A et B :

Private Sub Worksheet_Change(ByVal Target As Range)

    Dim Lig As Long

    If Target.Address(0, 0) <> "D1" And Target.Address(0, 0) <> "E1" Then Exit Sub
    If Target.Count > 1 Then Exit Sub

    Application.EnableEvents = False

    If Target.Address(0, 0) = "D1" Then

        Lig = Cells(Rows.Count, 1).End(xlUp).Row 'sur colonne A
        Cells(Lig + 1, 1).Value = Target.Value

    End If

    If Target.Address(0, 0) = "E1" Then

            Lig = Cells(Rows.Count, 2).End(xlUp).Row 'sur colonne B
            Cells(Lig + 1, 2).Value = Target.Value

    End If

    Application.EnableEvents = True

End Sub

Ce code est aussi à mettre dans le module de la feuille :

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

    If Target.Count > 1 Then Exit Sub

    If Target.Address(0, 0) = "D2" Then Range("E1").Select
    If Target.Address(0, 0) = "E2" Then Range("D1").Select

End Sub

Il permet de passer d'une cellule à l'autre (D1 --> E1, E1 --> D1) après saisie et validation par la touche Entrée pour plus de rapidité

Bonsoir, merci pour cette réponse, mais n'ayant aucune formation sur VBA, je vais écouter un tuto sur le sujet et essayer d'utiliser votre code.

Merci, je communiquerai sur les résultats.

Bonjour,

Voici un classeur test pour la saisie de la distance et l'altitude :

Merci, c'est exactement ce que voulais faire et en bidouillant, j'ai réussi à déplacer les cellules d'acquisition pour une mise en page différente.

Maintenant je vais pouvoir traiter les acquisitions, pour en déduire la distance totale parcourue, la montée totale, la descente totale et la durée totale du parcours.

Content de t’avoir Aidé