Coller valeur historique

Bonjour,

J'ai ce code qui met en historique des donné d'une feuille à l'autre mais je n'arrive pas a faire copier et coller les valeur seulement.

Actuellement ça copie aussi les formule et comme seulement une partie est mise en historique ça me donne des valeur faussé dans mon historique.

Quelqu'un peux m'aider?

Sub historique()

x = 0

With Sheets("BL")

ligne = .Columns(3).Find("*", , , , xlByColumns, xlPrevious).Row

For n = ligne To 11 Step -1

If Not IsEmpty(.Range("A" & n)) Then

x = x + 1

.Range("A" & n & ":L" & n).Select

Selection.Copy

Sheets("Histo Cde").Select

ligne2 = Sheets("Histo Cde").Columns(1).Find("*", , , , xlByColumns, xlPrevious).Row + 1

Sheets("Histo Cde").Range("A" & ligne2).Select

ActiveSheet.Paste

.Select

.Range("C" & n & ":E" & n).Select

Selection.ClearContents

End If

Next

End With

End Sub

Merci

Bonjour

Es tu à l'origine du code ?

As tu compris comment il fonctionne ?

Parce qu'il y a (à mon avis) plusieurs "erreurs" à corriger quant à la syntaxe et la méthode employée !

Bonjour,

Sans fichier test pas forcément facile d'interpréter mais voilà une façon de ne copier que les valeurs :

Sub historique()

    Dim FeBL As Worksheet
    Dim FeHisto As Worksheet
    Dim N As Long
    Dim Ligne As Long
    Dim Ligne2 As Long

    Set FeBL = Worksheets("BL")
    Set FeHisto = Worksheets("Histo Cde")

    With FeBL

        Ligne = .Cells(Rows.Count, 3).End(xlUp).Row

        If Ligne < 11 Then Exit Sub

        For N = Ligne To 11 Step -1

            If .Range("A" & N).Value <> "" Then

                Ligne2 = FeHisto.Cells(Rows.Count, 1).End(xlUp).Row + 1
                FeHisto.Cells(Ligne2, 1).Resize(1, 12).Value = .Range("A" & N & ":L" & N).Value

                .Range("C" & N & ":E" & N).ClearContents '<--- pourquoi n'en supprimer qu'une partie ? De C à E et non de A à L ?

            End If

        Next N

    End With

End Sub

Bonjour

@Theze

Tu as été plus perspicace que moi, code non indenté, non optimisé, et sans exemple en PJ... j'ai préféré attendre de meilleures explications

bonjour

conseil sans vouloir vous fâcher

https://forum.excel-pratique.com/viewtopic.php?f=10&t=123871

mon avis ; ne pas "archiver" comme on faisait avec des feulles de papier en 1970

on conserve toutes les données sur l'onglet

et on filtre

la magie d'Excel opére

amitiés

(..)

@jmd

Le problème avec Excel c'est sa simplicité apparente !

Trop sont nombreux qui voient des cases (là où il y a des cellules) à copier/coller dans tous les sens (au lieu de concevoir des tableaux structurés) parce que ils réfléchis (plutôt moins que assez) au but final et souvent même comment rendre son besoin plus pratique qu'avec l'outil papier/crayon !

[u]En conclusion effectivement et qu'on se le dise dans les chaumières, les entreprises, sur tous les toits... :

Excel n'est pas fait pour dessiner ![/u]

Voir ma signatue

Je pense : donc Excel (sous-entendu => je fais du Excel pas du papier/crayon=)

Par le long chemin d'Excel (sous-entendu => tu trouveras la solution)

et j'aurais même envie de rajouter In hoc Excel vinces