Cellule vers fenêtre filedialog explorateur windows

Bonjour,

J'ai dans une cellule un nom de fichier situé dans un répertoire.

J'aimerai, en cliquant dessus, afficher la fenêtre d'explorateur windows et que la valeur de ma cellule se transfère vers la barre de recherche (FileDialog il me semble)

afin que mon fichier soit recherché parmis mes répertoires comme si je faisais une recherche manuelle.

J'ai cherché un code pouvant me faire cela, en vain...

Merci pour votre aide.

Bonjour,

ci-dessous code événementiel à insérer dans la feuille contenant votre cellule ( exemple avec cellule = A1):

Option Explicit

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

    If Target.Address = Range("A1").Address Then Call recherche(Target.Value)

End Sub

ci-dessous code de recherche à insérer dans un module :

Sub recherche(nom_fichier)
    Dim répertoire As Variant
    Dim shl As Object, explorateur As Object, vue As Object
    Dim nb_fenêtres_shl As Integer

    '// affectation paramètre
    répertoire = ThisWorkbook.Path

    '// création objet de la classe Shell32
    Set shl = CreateObject("shell.application")

    '// ouverture d'une fenêtre explorateur et attente complétude de l'ouverture de la fenêtre
    nb_fenêtres_shl = shl.Windows.Count
    On Error Resume Next
    shl.Explore répertoire
    If Err.Number <> 0 Then MsgBox "répertoire non trouvé": Exit Sub
    While shl.Windows.Count = nb_fenêtres_shl: DoEvents: Wend

    '// création objets de la classe explorer (explorateur) et de la classe Shell32.ShellFolderView (vue)
    Set explorateur = shl.Windows(shl.Windows.Count - 1)
    Set vue = explorateur.Document

    '// Filtrage selon nom de fichier
    vue.FilterView nom_fichier

End Sub

Bonjour thev,

C'est exactement ça! merci beaucoup