Ouvrir un fichier (texte) dans le même classeur associé au code VBA

Bonsoir.

J'ai un problème pour ouvrir un fichier sur ma feuille excel.

En effet, j'ai utilisé la commande suivante:

dim Monfichier as Variant

Workbooks.OpenText Filename:=Monfichier, Origin:=xlWindow, _

StartRow:=1, DataType:=xlDelimited, semicolon:=True

Cela ouvre mon fichier, mais automatiquement dans un autre classeur, alors que je le veux sur celui avec lequel je travaille.

Du coup j'ai essayer de bidouiller mon programme mais rien n'y fait.

Quelqu'un pourrait m'éclaircir ?

Merci d'avance.

Slt et bienvenue sur le forum,

en changeant le

Workbooks.OpenText

avec:

Workbooks.Item.ActiveSheet.OpenText

peut être?

Je viens d'essayer cette manipulation mais ça ne marche pas.

Du coup pour plus de clarté, je vais mettre le programme que j'ai fait ci-dessous:

Sub macro2_selectfichier()

Dim Monfichier As Variant

'Classer les fichiers à partir de la deuxième ligne

Rows("2:2").Select

Selection.Insert Shift:=xlDown, CopyOrigin:=xlFormatFromLeftOrAbove

'Ouvrir le fichier (dans un autre classeur)

Monfichier = Application.GetOpenFilename

Workbooks.OpenText Filename:=Monfichier, Origin:=xlWindow, _

StartRow:=1, DataType:=xlDelimited, semicolon:=True

'Mais j'aimerais pouvoir l'ouvrir dans le même classeur où j'ai mon script VBA

End Sub

Donc si quelqu'un peut aider, ça serait super ^^

Et merci m3ellem1 pour l'aide que t'as proposé

Slt,

à tester.

Sub macro2_selectfichier()
Dim Monfichier As Variant

Monfichier = Application.GetOpenFilename("Text Files (*.txt), *.txt, Excel Files (*.xls), *.xls, All Files (*.*), *.*")

 If Monfichier <> False And Monfichier <> "" Then

   With ActiveSheet.QueryTables.Add(Connection:="TEXT;" & Monfichier, Destination:=Range("$A$2"))
            .FieldNames = True
            .PreserveFormatting = True
            .RefreshStyle = xlInsertDeleteCells
            .SaveData = True
            .AdjustColumnWidth = True
            .RefreshPeriod = 0
            .TextFileStartRow = 1
            .TextFileParseType = xlDelimited
            .TextFileSemicolonDelimiter = True
            .Refresh BackgroundQuery:=False
   End With

 End If

End Sub

Génial ça marche!

Merci beaucoup pour ton aide, tu gères

Excellemt