Boucle et gestion des erreurs

Bonjour,

j'ai réalisé un petit programme qui demande à l'utilisateur de donner le chemin d'accès à un fichier, puis le nom du fichier à ouvrir.

J'ai prévu une gestion des erreurs afin de ne pas planter le programme en cas d'erreur de frappe de l'utilisateur, si tel est le cas alors le programme reboucle pour de nouveau demander le chemin d'accès puis le nom du fichier .

Ce programme fonctionne une fois sur une erreur détecté puis si une deuxième erreur est faite alors il plante.

Merci pour votre aide.

ci dessous le programme en question :

Sub test()
Dim intFic As Integer
Dim strLigne As String
Dim CheminFichier As String
Dim Fichier As String

debut:
On Error GoTo erreur

CheminFichier = InputBox("Veuillez entrer le chemin du fichier", "Chemin du Fichier")
Fichier = InputBox("Veuillez entrer le nom du fichier", "Nom du Fichier")
CheminComplet = CheminFichier & "\" & Fichier & ".DAT"

intFic = FreeFile

Open CheminComplet For Input As intFic
Line Input #intFic, strLigne
Range("A1") = strLigne
Close intFic
Exit Sub

erreur:
Err.Clear
Response = MsgBox("tu as fait une erreur", vbRetryCancel, "Recommence")
If Response = 4 Then GoTo debut
End Sub

Slt,

essaie comme ca:

Sub test()
Dim intFic As Integer
Dim strLigne As String
Dim CheminFichier As String
Dim Fichier As String

debut:
On Error GoTo erreur

CheminFichier = InputBox("Veuillez entrer le chemin du fichier", "Chemin du Fichier")
Fichier = InputBox("Veuillez entrer le nom du fichier", "Nom du Fichier")
CheminComplet = CheminFichier & "\" & Fichier & ".DAT"

intFic = FreeFile

Open CheminComplet For Input As intFic
Line Input #intFic, strLigne
Range("A1") = strLigne
Close intFic
Exit Sub

erreur:
Err.Clear
Response = MsgBox("tu as fait une erreur", vbRetryCancel, "Recommence")
If Response = 2 Then
Exit Sub
Else: Resume debut
End If

End Sub

Bonjour à tous,

un essai sans gestion d'erreur

Sub test()
Dim intFic As Integer
Dim strLigne As String
Dim CheminFichier As String
Dim Fichier As String, MyFile as String

While MyFile = ""
     CheminFichier = InputBox("Veuillez entrer le chemin du fichier", "Chemin du Fichier")
     Fichier = InputBox("Veuillez entrer le nom du fichier", "Nom du Fichier")
     CheminComplet = CheminFichier & "\" & Fichier & ".DAT"
     MyFile = Dir(CheminComplet)
     If MyFile="" Then MsgBox ("Erreur de saisie")
Wend

intFic = FreeFile

Open CheminComplet For Input As intFic
Line Input #intFic, strLigne
Range("A1") = strLigne
Close intFic

End Sub

A+

m3ellem1 a écrit :

Slt,

essaie comme ca:

m3ellem1, merci pour cette solution qui fonctionne parfaitement. j'ai trouvé sur le web aussi : On Error GoTo -1 qui fonctionne également.

AlgoPlus a écrit :

Bonjour à tous,

un essai sans gestion d'erreur

A+

AlgoPlus, merci pour la solution sans traitement d'erreur.

J'ai lu qu'il fallait éviter d'utiliser le traitement d'erreur, par exemple On Error GoTo -1 que je cite plus haut, serait une solution à risque?

Quelqu’un pourrait-il m'en dire plus

d'avance merci