Insertion d'une pièce jointe a partir de mon Userform dans une cellule Exce

Bonjour;

J'ai créer deux boutons le premier pour la sélection (parcourir) l'endroit du fichier :

Private Sub CommandButton4_Click()

fileToOpen = Application.GetOpenFilename("All Files (*.*), *.*")

TextBox12 = fileToOpen

End Sub

et le deuxième pour l'insertion; mais le deuxième ne marche pas; voila mon code : (il passe toujours a la deuxiéme phase et il m'écrit "Pas de fichier sélectionné")

Private Sub CommandButton2_Click()

Dim OLEobj As OLEObject

Dim Gauche As Double, HautTop As Double, Largeur As Double, Hauteur As Double

Range("G" & J).Select

Gauche = Range("G" & J).Left

HautTop = Range("G" & J).Top

Largeur = Range("G" & J).Width

Hauteur = Range("G" & J).Height

If fileToOpen <> "" Then

Set OLEobj = ActiveSheet.OLEObjects.Add(Filename:=fileToOpen, Link:=False, DisplayAsIcon:=True, IconIndex:=0, IconLabel:=fileToOpen)

'OLEobj.Name = "LeFichier"

OLEobj.Left = Gauche

OLEobj.Top = HautTop

OLEobj.Width = Largeur

OLEobj.Height = Hauteur

Else

MsgBox "pas de fichier sélectionné"

End If

fileToOpen = ""

Unload Me

End Sub

Merci

Bonjour Belgacem,

Ton problème est-il toujours d'actualité?

Bonjour;

Oui

Bonsoir Belgacem,

Voici ma proposition :

Option Explicit                     'GVS Option systématique recommandée
Private Sub CommandButton4_Click()
    Dim fileToOpen As String
    fileToOpen = Application.GetOpenFilename("All Files (*.*), *.*")
    TextBox12 = fileToOpen
End Sub
Private Sub CommandButton2_Click()
    Dim OLEobj As OLEObject
    Dim Gauche As Double, HautTop As Double, Largeur As Double, Hauteur As Double
    Dim J As Long                   'GVS: Déclarer toutes les variables
    Dim fileToOpen As String        'GVS: Déclarer toutes les variables

    fileToOpen = TextBox12.Value    'GVS: Il faut récupérer la valeur stockée par CommandButton4_Click()
    J = 1                           'GVS: A ajuster en fonction de la ligne voulue
    Range("G" & J).Select
    Gauche = Range("G" & J).Left
    HautTop = Range("G" & J).Top
    Largeur = Range("G" & J).Width
    Hauteur = Range("G" & J).Height

    If fileToOpen <> "" Then
        Set OLEobj = ActiveSheet.OLEObjects.Add(Filename:=fileToOpen, Link:=False, DisplayAsIcon:=True, IconIndex:=0, IconLabel:=fileToOpen)
        'OLEobj.Name = "LeFichier"
        OLEobj.Left = Gauche
        OLEobj.Top = HautTop
        OLEobj.Width = Largeur
        OLEobj.Height = Hauteur
    Else
        MsgBox "pas de fichier sélectionné"
    End If

    fileToOpen = ""
    Unload Me

End Sub