Definir plage avec deux dates

Bonjour à tous

je cherche à définir une plage avec 2 deux dates que je récupère via 2 textbox du style

Plage = (Date1 : Date2). mais j'ai toujours des erreurs ! je veux utiliser après "Plage" en tant que variable dans une formule.

quelqu'un peut m'aider svp ça fait 3 jours que je suis sur l'affaire !

Merci de votre aide et bonne journée.

Bonjour Balawi, bonjour le forum,

T'aider sans le fichier qui va bien ?!... Difficile...

Bonjour,

En VBA, la recherche de dates est toujours assez épineuse mais en faisant la recherche sur des Long (valeur réelle stocké par Excel, ---> voir Value2 pour un Range), c'est plus concluant. Lis bien les commentaires pour comprendre ce que fait le code. En lieu et place des TextBox j'ai utilisé des InputBox() pour le test mais tu peux facilement remplacer par "TextBox1.Text", adapter aussi la plage :

Sub Test()

    Dim Plage As Range
    Dim PlgResult As Range
    Dim Cel1 As Range
    Dim Cel2 As Range
    Dim Date1 As Long
    Dim Date2 As Long
    Dim F As String

    'plage en colonne A
    Set Plage = Range("A1:A100")

    'mémorise le format
    F = Plage.NumberFormat

    On Error Resume Next
    'transforme les date saisies en Date puis en Long
    Date1 = CLng(CDate(InputBox("Date 1")))
    Date2 = CLng(CDate(InputBox("Date 2")))
    If Err.Number <> 0 Then MsgBox "Erreur de saisie !": Exit Sub

    'passe le format de la plage en standard
    Plage.NumberFormat = "General"

    'effectue la recherche sur des "Long"
    Set Cel1 = Plage.Find(Date1, , xlFormulas, xlWhole)
    Set Cel2 = Plage.Find(Date2, , xlFormulas, xlWhole)

    'repace en format initial
    Plage.NumberFormat = F

    'si une ou les deux dates ne sont pas trouvées, fin !
    If Cel1 Is Nothing Or Cel2 Is Nothing Then MsgBox "Dates non trouvées !": Exit Sub

    'défini la plage sur les deux bornes
    Set PlgResult = Range(Cel1, Cel2)

    affiche l 'adresse, c'est là que tu continu ton code...
    MsgBox PlgResult.Address(0, 0)

End Sub

Merci Theze je fais essayer