Objet recherché par une variable

Bonjour à tous,

Je viens de créer une fonction VBA qui me permet de coloriser un objet (avec clignotement).

Cela fonctionne très bien dès lors que l'objet est mentionné dans la macro VBA.

Hors je souhaiterai créer une variable qui aille chercher, dans mon exemple dans la cellule E1, sur laquelle est le nom de l'objet à coloriser (chair10, 11, 12 etc...).

Pouvez-vous m'aider à solutionner ma problématique.

Merci.

Bonjour,

J'ai modifié ton code en utilisant un autre minuteur afin de ne pas avoir de scintillement :

Private Declare Function GetTickCount Lib "Kernel32" () As Long

Sub Minuterie(Milliseconde As Long)

    Dim Arret As Long

    Arret = GetTickCount() + Milliseconde
    Do While GetTickCount() < Arret
        DoEvents
    Loop

End Sub
Sub rechercher2()

    Dim S As Shape
    Dim I As Integer
    Dim Nom As String

    Nom = Range("E1").Value

    Set S = Sheets("Feuil1").Shapes(Nom)

    With S.Fill

        .Visible = msoTrue
        .Transparency = 0
        .Solid

        Do While I < 10

            .ForeColor.RGB = RGB(0, 255, 0)
            I = I + 1
            Minuterie 200
            .ForeColor.RGB = RGB(255, 0, 0)
            Minuterie 200

        Loop

    End With

    'couleur bleue
    With S.Fill

        .Visible = msoTrue
        .ForeColor.TintAndShade = 0
        .Transparency = 0
        .Solid
        .ForeColor.ObjectThemeColor = msoThemeColorText2

    End With

End Sub

Pour un clignotement plus ou moins rapide, modifie la valeur de l'argument de la Sub "Minuterie" ici, 200 (0,2 seconde)

Bonjour ouize, Theze,

autre possibilité avec Sleep,

Bonjour,

Formidable !

C’est exactement ce que je voulais.

Merci à vous 2 pour le temps que vous avez accordé à ma problématique.

À bientôt chers amis.