Et si je remplace "X" par "J", "M" ou "AM" cela n'impacte pas la formule?
Ah bien si ... car jusqu'à présent je cherchais exactement un X
Dans ce cas il faut que je cherche "approximativement" un A
La formule devient :
=SIERREUR(INDEX(DECALER('Planning 2019'!$A$1;EQUIV($B6;'Planning 2019'!$C:$C;0);3;25);EQUIV("A";DECALER('Planning 2019'!$A$1;EQUIV($B6;'Planning 2019'!$C:$C;0);EQUIV(C$5;'Planning 2019'!$2:$2;0)-1;25);-1));"")
et de façon éclatée :
=SIERREUR(
INDEX(
DECALER('Planning 2019'!$A$1;EQUIV($B6;'Planning 2019'!$C:$C;0);3;25);
EQUIV("A";
DECALER('Planning 2019'!$A$1;
EQUIV($B6;'Planning 2019'!$C:$C;0);
EQUIV(C$5;'Planning 2019'!$2:$2;0)-1;
25);
-1)
);
"")
où
EQUIV($B6;'Planning 2019'!$C:$C;0)
recherche dans la colonne C la personne concernée (en fait la première cellule car elles ont fusionnées
EQUIV(C$5;'Planning 2019'!$2:$2;0)
recherche la date dans la ligne 2
ces valeurs sont injectées dans le code ci-après pour bâtir la matrice de recherche en partant de la cellule $A$1 (je mets -1 pour les colonnes car je pars déjà de la colonne 1, pas la peine pour la ligne car la première ne sert pas aux projets)
à noter la hauteur de la matrice de 25 car il y a 25 projets.
DECALER('Planning 2019'!$A$1;
EQUIV($B6;'Planning 2019'!$C:$C;0);
EQUIV(C$5;'Planning 2019'!$2:$2;0)-1;
25)
je fais maintenant une recherche par EQUIV de "A" dans cette matrice avec paramètre final -1 (et non 0 = recherche exacte) ... on obtient alors la ligne de la première valeur
EQUIV("A";
DECALER('Planning 2019'!$A$1;
EQUIV($B6;'Planning 2019'!$C:$C;0);
EQUIV(C$5;'Planning 2019'!$2:$2;0)-1;
25);
-1)
cette ligne va me permettre de capter la valeur par INDEX ici
DECALER('Planning 2019'!$A$1;EQUIV($B6;'Planning 2019'!$C:$C;0);3;25)
avec un décalage de 3 colonne pour le projet et 4 pour le libellé.