Modification de liens

Bonjour,

J'ai un classeur excel avec les onglets protégés. J'ai besoin de faire une macro qui déprotège les onglets (ca pas de problème), puis qui ouvre la fenêtre "modifier les liaisons" (on peut l'ouvrir mais impossible à mettre à jour lorsque le classeur a une feuille protégé), et j'aimerai savoir ce qu'il faut indiquer dans le code pour que lorsque je fait "fermer" la fenêtre "modifier les liaisons", il y ai un autre code qui reprenne le relais et me verrouille toutes les feuilles visibles.

Merci par avance

Bonjour,

Il y a t'il plusieurs liens ?

Veux-tu modifier un lien ou le supprimer ?

Bonjour

Il y a plusieurs liens, et le nombre n'est pas définis. Je peux en avoir 1 à changer comme 4.

Par contre, peut être une piste, j'ai besoin de modifier tous les liens et de les refaire pointer sur le fichier lui même.

Le plus important c'est qu'il ne faut pas déprotéger les feuilles et qu'on ai la main sur celles ci pendant l’exécution de la macro. (J'ai des petits malins qui vont me flinguer des formules ou tricher sinon).

Merci pour ton aide en tout cas

Bon dimanche.

re,

à tester,

Sub Modifier_ExcelLinks()
For i = 1 To Worksheets.Count
  Worksheets(i).Activate
  Call DeProtege
Next

For Each lk In ActiveWorkbook.LinkSources(Type:=xlLinkTypeExcelLinks)
  ActiveWorkbook.ChangeLink lk, ThisWorkbook.FullName, xlExcelLinks
Next

For i = 1 To Worksheets.Count
  Worksheets(i).Activate
  Call Protege
Next
End Sub

Sub DeProtege()
ActiveSheet.Unprotect Password:="MotdePasse"
End Sub

Sub Protege()  'à adapter
'protection de la feuille active
With ActiveSheet
'permet filtre et grouper lignes et colonnes
    .EnableAutoFilter = True
    .EnableOutlining = True

    'pour les options de protection que vous ne désirer pas autoriser: changer True pour False
    .Protect Password:="MotdePasse", _
        DrawingObjects:=True, _
        Contents:=True, _
        Scenarios:=True, _
        AllowFormattingCells:=True, _
        AllowFormattingColumns:=True, _
        AllowFormattingRows:=True, _
        AllowInsertingColumns:=True, _
        AllowInsertingRows:=True, _
        AllowInsertingHyperlinks:=True, _
        AllowDeletingColumns:=True, _
        AllowDeletingRows:=True, _
        AllowSorting:=True, _
        AllowFiltering:=True, _
        AllowUsingPivotTables:=True, _
        UserInterfaceOnly:=True
 End With
End Sub

Bonjour

Ca fonctionne parfaitement ! C'est encore mieux que ce que je pensais !

Merci beaucoup