Sélectionner la feuille où je lance la macro

Salut,

j'aimerai savoir comment je peux sélectionner la feuille d'où je lance ma macro.

ci-joint mon code (qui ne marche pas)

Sub ReImport()

Dim O_Cell As Object
Dim C_UI As String

        C_UI = ActiveSheet.Range("N16") 'valeur à chercher
        Application.Goto Reference:=Sheets("TABLEAU HISTORIQUE").Range("A1:J1000") ' "UI" est le nom de la zone de recherche
        Set O_Cell = Selection.Find(C_UI) ' recherche de la valeur
        If Not O_Cell Is Nothing Then 'si l'objet O_Cell contient les coordonnées de la cellule
                O_Cell.Select ' sélection de la cellule

O_Cell.Offset(3, -2).Value = ActiveSheet.Range("M6")
O_Cell.Offset(3, -1).Value = ActiveSheet.Range("N6")

                         End If

End Sub

Le problème est lors de ma saisie de l'activesheet (qui devrait être la feuille ou j'utilise la macro). Le problème est que le nom de la feuille est varibale... Des idées?

MERCI

Bonjour,

Essaie ceci :

Sub ReImport()
Dim C_UI As String, O_Cell As Range
    With ActiveSheet
        C_UI = .Range("N16")
        With Worksheets("TABLEAU HISTORIQUE").Range("A1:J1000")
            Set O_Cell = .Find(what:=C_UI, LookIn:=xlValues, lookat:=xlWhole)
        End With
        If Not O_Cell Is Nothing Then
            O_Cell.Offset(3, -2).Value = .Range("M6")
            O_Cell.Offset(3, -1).Value = .Range("N6")
        End If
    End With
End Sub

Salut,

NICKEL ^^

Re,

Pense à clore le sujet !...