Supprimer toutes les valeurs des textbox et checkbox

je cherche une macro qui me permet de supprimer toutes les valeurs de mes textbox et checkbox sachant que j'ai plus de 40 texbox et 20 checkbox

j'ai essayé ceci en VBA qui fonctionne :

textbox1.value = ""

checkbox.value = false

mais je dois recopier 40 fois la même ligne.

Existe-t-il une formule de type :

au clic, mettre les valeurs des textbox de 1 à 40 = ""

& mettre les valeurs des checkbox de 1 à 20 = false

précision je n'ai pas créer de userform je suis directement sur la page de calcul

Merci d'avance

Bonjour,

Voici une solution :

Sub Test()
    Dim oObjet As Object

    ' Boucle sur tous les objects
    For Each oObjet In Me.OLEObjects
        ' TextBox
        If TypeOf oObjet.Object Is msforms.TextBox Then
            oObjet.Object.Text = ""
        ' CheckBox
        ElseIf TypeOf oObjet.Object Is msforms.CheckBox Then
            oObjet.Object.Value = False
        End If
    Next oObjet
End Sub

Merci ca fonctionne nikel super !!!!

Bonjour, je suis nouveau mais je m'informe assez souvent sur le forum et je suis très interressé par ta solution readi , j'ai essayé de m'en servir pour mon cas mais je comprend pas trop ton code.

mon cas : j'ai crée une fenêtre en VBA et lorsque je clique sur un bouton ("Annuler") la fenêtre disparait et je voudrais que les TextBox, OptionButton devienne vide. Pour eviter comme pour gregsz de devoir retaper a chaque fois les même lignes de code.

Si tu pouvais m''expliquer ton code ça serai sympa

Ah oui oublié de préciser, j'ai essayé ce genre de chose mais ça marche pas trop :

Private Sub CommandButton1_Click()

'OptionButton1 = False
'OptionButton2 = False
'OptionButton3 = False
'OptionButton4 = False
'OptionButton5 = False

'TextBox1.Value = Clear
'TextBox2.Value = Clear
'TextBox3.Value = Clear
'TextBox4.Value = Clear
'TextBox5.Value = Clear
'TextBox6.Value = Clear
'TextBox7.Value = Clear
'TextBox8.Value = Clear
'TextBox9.Value = Clear
'TextBox10.Value = Clear
'TextBox11.Value = Clear
'TextBox12.Value = Clear
'TextBox13.Value = Clear
'TextBox14.Value = Clear

For i = 1 To 5
    OptionButton(i) = False
    TextBox(i).Value = Clear
Next i

Range("A39:A50", "B40:B43").Select
Selection.Value = Clear

Cells(12, 4).Value = Clear
ComboBox1.ListIndex = Clear

SaisieAvion.Hide

End Sub

Bonjour,

Voici une possibilté :

Sub Test() 
    Dim oObjet As Object 

    ' Boucle sur tous les objects 
    For Each oObjet In Me.OLEObjects 
        ' TextBox 
        If TypeOf oObjet.Object Is msforms.TextBox Then 
            oObjet.Object.Text = "" 
        ' CheckBox 
        ElseIf TypeOf oObjet.Object Is msforms.CheckBox Or TypeOf oObjet.Object Is msforms.OptionButton Then 
            oObjet.Object.Value = False 
        End If 
    Next oObjet 
End Sub

Si cela ne convient pas, il faudrait un extrait du fichier.

Bonjour,

Ritchi, si j'ai bien compris, tu fais apparaître un UserForm avec des TextBoxs et des CheckBoxs...

Pour un USF, la procédure est différente, on n'utilise pas d'OleObjects, mais des Controls..

Exemple :

For i = 1 to 8
Me.Controls("TextBox" & i).Value = ""
Me.Controls("CheckBox" & i).Value = False
Next i

CEPENDANT, nul besoin de ce code pour remettre à 0 tous tes TextBoxs, ni CheckBoxs, avec un USF

Au lieu d'utiliser :

UserForm1.Hide, ou Me.Hide

utilise :

Unload Me

Tout est réinitialisé....

Bon courage

J'ai réédité mon message pour que tu puisses voir un peu ce que je recherche

Super merci bcp j'ai test "Unload Me" et ça a l'air de fonctionner

Tu m'enleves une grosse épine du pied

Encore Merci

Re,

ça a l'air de fonctionner

Non, ça fonctionne....