Planifier la charge en fonction d'une grille de jour et une date de début
Bonjour à tous,
J'ai essayé de chercher la solution sur le forum, mais je n'ai pas trouvé mon bonheur
J'essaye de faire un fichier Excel pour résoudre des problèmes de surcharge de mes équipes car je pense que j'ai une mauvaise gestion des temps affectés aux projets, et cela me tient à cœur d'avoir des conditions de travail saines !
Nous avons des missions de 24, 36 et 48 mois avec des jours prédéfinis mois par mois.
Afin de pouvoir anticiper la charge, je souhaiterais créer une sorte de calendrier qui décale les jours de missions prévus en fonction de la date de début de mission.
J'ai dans un onglet la liste de tous les projets TYPE avec la liste de jours mois par mois sur 24, 36 ou 48 mois, ce qui correspond en réalité à:
| Nom | Mois 1 | Mois 2 | Mois 3 | ... |
| AUTOMOBILE | 1 | 1 | 2 | ... |
Par exemple :
Mois 1 : 1 jour car réunion de lancement
Mois 2 : 1 jour car visite de site
Mois 3 : 2 jours car contrôle sur site et rapport...
et je voudrais sur un autre onglet:
Une liste déroulante de choix avec le type de projets, je mets la date de début à côté par exemple "Avril 2018" donc je voudrais que les jours de projets se mettent dans le planning qu'à partir d’avril 2018 ( les jours qui correspondent à la mission, car chaque mission a des jours différents)
Je ne suis pas débutante en Excel mais je n'ai pas trouvé de solution simple (si possible pas de macro car fichier mis en ligne après
J'ai joint un exemple en dessous
Merci d'avance pour vos retours,
Tatawy
Bonjour à tous,
Svppp Help
J'aimerais obtenir un outils qui permettent de montrer que la charge n'est pas adaptée au mois de mes équipes !
Bonjour,
Je ne peux malheureusement pas aider car lorsque je souhaite télécharger le fichier je tombe sur le message d'erreur suivant :
"Le fichier joint sélectionné n’est plus disponible."
Pourrais-tu réenvoyer ton fichier?
Nous verrons ensuite si on trouve ou non des solutions,
Merci
EDIT: Je ne sais pas pourquoi, mais en relançant la page et en réessayant de télécharger le fichier, ça marche, soucis de chargement de mon côté je dirais, pas besoin de renvoyer le fichier.
Re-bonjour!
Avec une formule matricielle je peux proposer cette solution :
Si tu as besoin d'explications sur la formule je peux expliquer
Merci de me dire si ce que je propose correspond bien au résultat attendu
Oh mais c'est génial , c'est exactement ça !!!!
est ce que c'est possible de m'expliquer la formule utilisée ? Histoire que je puisse bidouiller si l'occasion s'y prête?
Merci merci ,
Votre pseudo est très bien adapté
Laure
Pas de soucis, je vais expliquer
Alors la formule pour la case avril par exemple :
=SI(H$1<$D2,"",RECHERCHEV($C2,'Liste de projet'!$A$2:$BI$4,COLONNE('Liste de projet'!$B$1)+COLONNE()-MIN(SI($E$1:$BL$1>=$D2,COLONNE($E$1:$BL$1),"")),FAUX))
Pour commencer regardons la première fonction, il s'agit d'un SI, ce que je teste c'est que le mois qui est sur la même colonne que la cellule soit au moins supérieur à la date de debut, sinon pas la peine de faire de calcul, on renvoie une valeur vide.
Sinon on renvoie le résultat d'une recherche.
Maintenant il faut se pencher d'avantage sur la recherche, il y a beaucoup de choses dedans car je veux qu'elle soit dynamique (si on ajoute ou supprime des colonnes ça ne plante pas).
RECHERCHEV($C2,'Liste de projet'!$A$2:$BI$4,COLONNE('Liste de projet'!$B$1)+COLONNE()-MIN(SI($E$1:$BL$1>=$D2,COLONNE($E$1:$BL$1),"")),FAUX)
Donc on va rechercher le type de projet dans la liste de projet qui est dans la deuxième feuille et on renvoie le numéro de colonne calculé par une expression particulièrement longue, en demandant une correspondance exacte sur la valeur cherchée
Maintenant le numéro de colonne :
COLONNE('Liste de projet'!$B$1)+COLONNE()-MIN(SI($E$1:$BL$1>=$D2,COLONNE($E$1:$BL$1),""))
Il est calculé de la façon suivante :
On prend la première colonne des mois dans la liste à laquelle on ajoute la différence suivante :
Le numéro de colonne actuel moins le numéro de la première colonne dont le mois et l'année sont supérieurs ou égaux à ceux de la date saisie dans la colonne D
Ce calcul est fait de la façon suivante car il faudra aller chercher d'abord la colonne 2 pour le premier mois, puis le 3ème... Le problème étant qu'on ne va pas toujours chercher la colonne 2 au mois d'avril, ça dépend du mois de départ qui a été renseigné, c'est pour cette raison que je fais ce calcul. Pour le mois d'avril par exemple (colonne 8), je vais avoir la chose suivante :
colonne = 2 + 8 - 8 = 2
pour mai : colonne = 2 + 9 - 8 = 3
et ainsi de suite, mais si on choisit plutôt de commencer le projet en mars (colonne 7) par exemple, le calcul será le suivant :
pour avril : colonne = 2 + 8 - 7 = 3
Pour calculer le numéro de la première colonne dont le mois et l'année sont supérieurs ou égaux à ceux de la date saisie dans la colonne D on utilise ces formules :
MIN(SI($E$1:$BL$1>=$D2,COLONNE($E$1:$BL$1),""))
On prend le numéro de colonne minimum qui correspond à notre test, le test est ensuite fait par une fonction SI qui renvoie soit le numéro de colonne, soit rien du tout.
La fonction MIN se traduit par "la première".
Donc si on remonte toute ce qu'on a fait dans cette formule :
Si on est pas dans un mois antérieur à celui de départ, on va chercher le nombre de jours travaillés dans le mois n + x, n étant le premier mois, et x le nombre de mois écoulés entre celui actuel et celui debut de projet.
J'espère avoir été clair