Macro copier une ligne si condition respéctée

Bonjour

Voila jai un gros problème je n'arrive pas à faire la macro suivante:

Si Statut = 100% - Validée (feuille Funnel Capsa NEW colonne i ), alors recopier, à partir de la feuille Funnel Capsa NEW, dans KPI PRODUCTION :

CLIENT en commençant à B7 , N° PROJET C7, ACTIVITE D7, DATE VALIDATION E7 ET MOIS F7

et

Je n'arrive pas non plus à créer une deuxième macro qui reporte les nouvelles lignes rentrées (de l'onglet Felix jusqu'a l'onglet Louis santi) dans l'onglet Funnel NEW CAPSA et cela pour les information De la colonne A à la colonne i

Merciiiiiiiii

Sauvez moi sil vous plait

Bonjour Capos, bonjour le forum,

Une proposition avec la macro événementielle Change ci-dessous :

Private Sub Worksheet_Change(ByVal Target As Range)
Dim OS As Worksheet 'déclare la variable OS (Onglet Source)
Dim OD As Worksheet 'déclare la variable OD (Onglet Destination)
Dim DEST As Range 'déclare la variable DEST (cellule de DESTination)

Set OS = Worksheets("FUNNEL CAPSA_NEW") 'définit l'onglet source OS
Set OD = Worksheets("Production KPI") 'définit l'onglet destination OD
If Target.Column <> 9 Then Exit Sub 'si le changement a lieu ailleurs qu'en colonne 9 (=I), sort de pa procédure
If Target.Value = "100% - Validée" Then 'si la cellule modifiée vaut "100% - Validée"
    Set DEST = OD.Cells(Application.Rows.Count, "B").End(xlUp).Offset(1, 0) 'définit la cellule de destination DEST
    Cells(Target.Row, 1).Copy DEST 'copie le commercial
    Cells(Target.Row, 4).Copy DEST.Offset(0, 1) 'copie le numéro de projet
    Cells(Target.Row, 5).Copy DEST.Offset(0, 2) 'copie l'activité
    Cells(Target.Row, 7).Copy DEST.Offset(0, 3) 'copie la date de validation/refus
    Cells(Target.Row, 8).Copy DEST.Offset(0, 4) 'copie le mois
End If 'fin de la condition
End Sub

En I5, choisis l'option 100% - Validée...

Merci beaucoup !

malheureusement je n'arrive pas à la faire marcher, si cela ne te derange pas pourrais tu l'intégrer dans mon fichier en mettant

des boutons pour les deux macros ?

Merci tu me sauverais la vie

Voici...

Merci c'est exactement cela !!! Mais cela copie des doublons, comment faire ?

Savez vous si c'est possible que à partir des onglets (Felix jusqu'à Louis santi), l'onglet Funnel capsa NEW soit alimenté,

par exemple si Felix rentre des données dans son onglet, elles se rentrent automatiquement dans l'onglet Funnel Capsa NEW,

ou alors une macro qui copies seulement les lignes qui sont nouvelles pour pas qu'il y ait de doublons

Et dernier dérangement... pouvez vous me montrer le codage de la macro pour que j'essaye d'apprendre svp ??

Merci pour votre aide c'est très gentil

Re,

Peut-être aurais-je le temps de regarder ça demain mais je ne garantis rien... Le code se trouve dans le composant Feuil1 (Production KPI), je te le recopie ici :

Private Sub CommandButton1_Click()
Dim OS As Worksheet 'déclare la variable OS (Onglet Source)
Dim OD As Worksheet 'déclare la variable OD (Onglet Destination)
Dim CEL As Range 'déclare al variable CEL (CELlule)
Dim DEST As Range 'déclare la variable DEST (cellule de DESTination)

ActiveCell.Select 'enlève le focus au bouton
Set OS = Worksheets("FUNNEL CAPSA_NEW") 'définit l'onglet source OS
Set OD = Worksheets("Production KPI") 'définit l'onglet destination OD
For Each CEL In OS.Range("I5:I" & OS.Cells(Application.Rows.Count, 9).End(xlUp).Row) 'boucle sur toutes les cellules de la colonne I
    If CEL.Value = "100% - Validée" Then 'condition : si la cellule CEL vaut "100% - Validée"
        Set DEST = OD.Cells(Application.Rows.Count, "B").End(xlUp).Offset(1, 0) 'définit la cellule de destination DEST
        OS.Cells(CEL.Row, 1).Copy DEST 'copie le commercial
        OS.Cells(CEL.Row, 4).Copy DEST.Offset(0, 1) 'copie le numéro de projet
        OS.Cells(CEL.Row, 5).Copy DEST.Offset(0, 2) 'copie l'activité
        OS.Cells(CEL.Row, 7).Copy DEST.Offset(0, 3) 'copie la date de validation/refus
        OS.Cells(CEL.Row, 8).Copy DEST.Offset(0, 4) 'copie le mois
    End If 'fin de la condition
Next CEL
End Sub

Merci beaucoup !!!

Bonjour Capos, bonjour le forum,

Ce que tu demandes correspond exactement au premier code que je t'ai envoyé avec la macro événementielle Change. Ce genre de macro fonctionne automatiquement sans avoir besoin d'un bouton. Dans ton cas elle va s'exécuter chaque fois que tu vas modifier une cellule dans l'onglet. Comme j'ai bloqué son action à la colonne 9 (=I) et à la valeur 100% - Validée, elle n'agira que dans ces deux conditions. Plus de doublons puisque qu'une fois qu'elle a agi c'est fini... Pour que cela fonctionne dans tous les onglets désirés il m'a suffit de copier le code dans tous ces onglets...

Le seul inconvénient : si dans une ligne tu sélectionnes 100% - Validée puis tu te rends compte que tu t'es trompé et tu modifies (par exemple 25% - Attente"), Il faudra penser à effacer la ligne de l'onglet Production KPI car la macro aura agi...

Ton fichier modifié.