Value! avec fonction si
Bonjour a tous et à toutes!
Je viens vers vous car je m'arrache les cheveux sur une formule.
Je suis sûr que c'es trien de méchant mais après 3 heures de recherches je sèche.
Voilà le soucis:
=SI(ET(B4=1;B5<=14360);"Très Modeste";SI(ET(B4=1;B5>14360;B5<=18409);"Modeste";"Classique"))
La ça fonctionne nikel. Le problème est que B4 peut être =2 ce qui me donne d'autres valeurs à savoir:
=SI(ET(B4=2;B5<=21001);"Très Modeste";SI(ET(B4=2;B5>21001;B5<=26923);"Modeste";"Classique"))
Une fois de plus, collé dans la cellule à coté ça fonctionne nikel.
Mais quand je veux mettre dans la meme cellule alors là j'ai mon erreur valeur...
=SI(ET(B4=1;B5<=14360);"Très Modeste";SI(ET(B4=1;B5>14360;B5<=18409);"Modeste";"Classique"));
SI(ET(B4=2;B5<=21001);"Très Modeste";SI(ET(B4=2;B5>21001;B5<=26923);"Modeste";"Classique"))
Je pense à une erreur de syntaxe mais je ne trouve pas.
Merci par avance pour vos réponses!
Bonjour
=SI(OU(ET(B4=2;B5<=21001);ET(B4=1;B5<=14360));"Très Modeste";SI(OU(ET(B4=2;B5>21001;B5<=26923);ET(B4=1;B5>14360;B5<=18409));"Modeste";"Classique"))Wouhaou merci infiniement!
pourriez-vous m'expliquer en quelques mots mon erreur?
Merci par avance.
L'erreur est une erreur de syntaxe, tu as juxtaposé 2 "SI" séparés par un point virgule
=SI(ET(B4=1;B5<=14360);"Très Modeste";SI(ET(B4=1;B5>14360;B5<=18409);"Modeste";"Classique"));
SI(ET(B4=2;B5<=21001);"Très Modeste";SI(ET(B4=2;B5>21001;B5<=26923);"Modeste";"Classique"))on aurait pu relier les 2 "SI" par & puisqu'elles produisent du texte, mais on aurait eu dans ce cas un résultat du type ModesteClassique par exemple !!
il fallait combiner les conditions entre elles
Bonjour Beatsaucue, Steelson,
je propose d'abord cette 1ère formule, assez optimisée :
=SI(OU(B4<1;B4>2);"?";SI(OU(ET(B4=1;B5>18409);ET(B4=2;B5>26923));"Classique";SI(OU(ET(B4=1;B5<=14360);ET(B4=2;B5<=21001));"Très ";"") & "Modeste"))
puis cette 2ème formule, encore plus optimisée :
=SI(OU(B4<1;B4>2);"?";SI(B5>18409+8514*(B4=2);"Classique";SI(B5<=14360+6641*(B4=2);"Très ";"") & "Modeste"))
dhany
Bonjour et merci pour vos réponses.
J'ai bien avancé depuis mais je reviendrai surement vers vous car ce n'est que le premier tiers de mon projet.
A plus tard et encore MERCI
Merci pour ton retour !
dhany
Bonjour à tous!
Merci beaucoup pour vos conseils mais voilà ça devait arriver j'ai un new prob qui est le meme...
Voici la formule:
=SI(ET(B6="Classique";B7="Combustible";B11="OUI";B9="Combles");B10*2;"");SI(ET(B6=Modeste;B7="Combustible";B11="OUI";B9="Combles");B10*3;"")
et j'ai des tas de conditions.
pensez-vous qu'il y aurais une manière plus simple faire?
Merci par avance
Bonjour Beatsaucue,
Je te propose cette formule (à bien vérifier !) :
=SI(ET(B7="Combustible";B11="OUI";B9="Combles");SI(B6="Classique";B10*2;SI(B6="Modeste";B10*3;""));"")
Cette formule est déjà dans ce fichier :
dhany
merci beaucoup j'essaie et je tedis.
Comprends tu la compléxité de l'ensemble?
tu as le tableau d'origine en feuille 2 dans le fichier
Merci c'est génial!
Donc maintenant, il faut que jutilise ce même modèle pour toutes les option possibles combinées au classique, modeste, etc...
J'espere m'en sortir lol!
a plus je marque résolu
Voici la formule:
=SI(ET(B6="Classique";B7="Combustible";B11="OUI";B9="Combles");B10*2;"");SI(ET(B6=Modeste;B7="Combustible";B11="OUI";B9="Combles");B10*3;"")
Cela veut dire que tu n'a pas appris grand chose du post précédent.
Revois la réponse ici https://forum.excel-pratique.com/viewtopic.php?p=649110#p649110
Tu ne dois pas aligner tes formules à la queue leu leu mais combiner les conditions
Bonjour et Merci Steelson!
C'est juste qu'il y a tellement de conditions que je m'y perd!
mais Ok je vais plus me creuser la tête!
A ta disposition
notre objectif (le mien) est plus pédagogique : transmettre et rendre plus autonome (moi-même je suis devenu plus autonome grâce à ce forum)
Toppissime!
Alors je pense avoir compris la logique.
Je suis sûr que ce n'est pas optimisé mais ça marche!
Tiens je te met ce que j'ai fais.
J'espere que je peux en mettre des tas dans la cellule car j'ai encore plein de conditions a rentrer...
=SI(OU(ET(B9="Combles";B11="Oui";B6="Classique"));B10*2;
SI(OU(ET(B9="Combles";B11="Non";B6="Classique"));B10*6;
SI(OU(ET(B9="Combles";B11="Oui";B6="Modeste"));B10*3;
SI(OU(ET(B9="Combles";B11="Non";B6="Modeste"));B10*6;
SI(OU(ET(B9="Combles";B11="Oui";B6="Très modeste"));B10*6;
SI(OU(ET(B9="Combles";B11="Non";B6="très modeste"));B10*12))))))
on peut toujours optimiser, mais si cela fonctionne l'objectif est atteint !
Bonjour Beatsaucue,
Dans une de tes formules, il y avait à la fois : "Classique", "Modeste", "Très Modeste" ; alors pour ton fichier "Calculateur CEE.xlsx", feuille "Prime iso H1", comment se fait-il qu'il manque la dernière partie ? il y a "Classique" en B3:E10 ; il y a "Modeste" en F3:I10 ; il manque la partie "Très Modeste", qui devrait normalement être en J3:M10 !
Peux-tu mettre dans ton prochain post un fichier plus complet, avec cette dernière partie ?
Sur "Feuil1", en A8 : "Nombre de fenêtres" ; en B8 : liste 1 à 17 ; il semble que le calcul de la prime soit aussi en fonction de cette donnée, mais y'a aucune info du style « si tant de fenêtres alors telle ou telle chose pour le calcul de la prime » !
Pour faire ce genre d'exo, il faut connaître toutes les conditions dès le départ ! faut pas rajouter des bribes au coup par coup !
Si tu fournis un fichier complet, sans données manquantes, je crois que je pourrai faire quelque chose de très bien.
À te lire pour la suite.
dhany
Bonjour Dhany comment va?
Oui en effet le très modeste n'y apparait pas car pour le très modeste il faut faire la prime des modestes x 2. Ca ne s'invente pas
Mais merci à tous mon fichier est terminé grâce à vos consil et l'appli android est faite aussi!
Have a nice day