Actualisation d'un croisé via un bouton se trouvant sur un autre onglet

Question

C’est un peu compliqué à expliquer, mais je vais tout de même essayer… J’ai un premier onglet « Rapport » (protégé avec un mot de passe) qu’un opérateur complet à chaque réception de marchandise. Dès qu’il a terminé il clique sur un bouton que j’ai affecté à une Macro qui va enregistrer et imprimer le document (et ainsi de suite). Maintenant, une autre personne consulte ce document (en lecture seule), mais sur un autre onglet « TEST » qui est caché et aussi protégé par un mot de passe, il s’agit un croisé dynamique qui fait référence à l’onglet « Rapport ». Ce que j’aimerai faire : actualiser la croisée dynamique automatiquement lorsque l’opérateur clique sur le bouton qui est affecté à la macro enregistrer et imprimer mais j’obtiens toujours l’erreur ci-dessous au niveau (ActiveSheet.PivotTables("Tableau croisé dynamique2").PivotCache.Refresh ), pour info le code ci-dessous est uniquement de la première partie de la macro (actualisation du croisé, ensuite je vais intégrer l’enregistrement et l’impression). Est-ce qu’il y a une solution d’actualiser le croisé sans que l’opérateur puis avoir accès à l’onglet "TEST" ? Merci pour votre aide. Olivier Sub Macro1() ' ' Macro1 Macro ' ' ActiveSheet.Unprotect Sheets("Rapport").Select Sheets("TEST").Visible = True ActiveCell.Offset(-8, -2).Range("A1").Select ActiveSheet.PivotTables("Tableau croisé dynamique2").PivotCache.Refresh Sheets("TEST").Select ActiveWindow.SelectedSheets.Visible = False ActiveSheet.Protect DrawingObjects:=False, Contents:=True, Scenarios:= _ False, AllowSorting:=True, AllowFiltering:=True, AllowUsingPivotTables:= _ True ActiveWorkbook.Save End Sub...

Jean-Eric · Answer

Le bouton est sur quelle feuille ? Le TCD est sur quelle feuille ? Quelles sont les feuilles protégées ? Les feuilles protégées par mot de passe ? C'est un peu confus, surtout à la lecture de ton code. On n'a pas besoin de sélectionner ou d'activer la feuille du TCD, pour actualiser ce dernier !... Peux-tu joindre un fichier ? Cdlt...

dhany · Answer

Bonjour Larouve , Je trouve le titre de ton sujet « Actualisation d'un croisé » très intéressant ! malheureusement, je crois qu'il n'est plus d'actualité : les guerres des Croisades sont terminées depuis longtemps, mais j'admets volontiers qu'anoblir un Croisé avant qu'il parte au combat était une forme d'actualisation (une sorte de rite d'initiation, quoi) . Heureusement, notre Grand Historien Jean-Eric , expert en TCD médiévaux de toutes sortes, t'a posé exactement toutes les questions qu'il fallait ! (un grand merci à lui ) dhany...

Jean-Eric · Answer

Un début de réponse à méditer. Cdlt. Public Sub Data_processing() Dim wb As Workbook Dim ws As Worksheet, ws2 As Worksheet Dim lo As ListObject Set wb = ActiveWorkbook Set ws = wb.Worksheets("Rapport") Set lo = ws.ListObjects(1) Set ws2 = wb.Worksheets("TEST") wb.Unprotect ws.Unprotect With lo .ListRows.Add .Sort.SortFields.Add .ListColumns(1).DataBodyRange, xlSortOnValues, xlAscending .Sort.Apply .Sort.SortFields.Clear End With ws.Protect With ws2 .Unprotect .PivotTables(1).PivotCache.Refresh .Protect End With With wb .Protect Structure:=True, Windows:=False .Save End With End Sub...

Jean-Eric · Answer

Re,

Une nouvelle proposition à étudier.

Cdlt.

13larouve.xlsm (62.47 Ko)

Option Explicit
Option Private Module

Public Const PWD As String = "excel"

Public Sub Data_processing()
Dim wb As Workbook
Dim ws As Worksheet, ws2 As Worksheet
Dim lo As ListObject

    Set wb = ActiveWorkbook
    Set ws = wb.Worksheets("Rapport")
    Set lo = ws.ListObjects(1)
    Set ws2 = wb.Worksheets("TEST")

    wb.Unprotect Password:=PWD
    ws.Unprotect Password:=PWD

    With lo
        .ListRows.Add
        .Sort.SortFields.Add .ListColumns(1).DataBodyRange, _
                             xlSortOnValues, _
                             xlDescending
        .Sort.Apply
        .Sort.SortFields.Clear
    End With

    With ws
        .EnableAutoFilter = True
        .Protect Password:=PWD, _
                 userinterfaceonly:=True, _
                 AllowSorting:=True, _
                 AllowFiltering:=True
    End With

    With ws2
        .Unprotect Password:=PWD
        .PivotTables(1).PivotCache.Refresh
        .EnablePivotTable = True
        .Protect Password:=PWD, _
                 userinterfaceonly:=True, _
                 AllowUsingPivotTables:=True
    End With

    With wb
        .Protect Password:=PWD, Structure:=True, Windows:=False
        .Save
    End With

End Sub

Jean-Eric · Answer

Je renvoie le classeur pour l'histoire de la feuille TEST. Mais dans la mesure ou tu as demandé une protection du classeur, tu ne pourras pas l'afficher. Pour le reste, je ne comprends pas !... A l'insertion d'une ligne, je t'ai proposé 2 tris (ascendant, puis descendant). La procédure reprend ta demande !... Cdlt. Nota : comment as-tu fait pour insérer un nouvel article ...