Vider la fenetre insérer

Bonjour

quand on fait un clique droit sur une feuille excel puis on choisi insérer, une fenêtre s'ouvre avec plusieurs types (feuille,Graphique,Macro Ms Excel...) il y a t'il un moyen de vider cette fenêtre et ne laisser que le type feuille?

Merci pour vos reponses

Bonjour drdidji,

je ne sais pas si on peut formater la fenêtre, mais on peut contourner le problème en VBA. On efface l'option "Insérer..." et on la remplace pour une nouvelle option que l'on définie. Voici le code à placer dans un module:

Public MainMenu As CommandBarControl

'Mise en place du nouveau menu
Public Sub MiseEnPlace()
    EffacerAncienInserer
    NouveauInserer
End Sub

'Efface l'ancien menu Insérer...
Sub EffacerAncienInserer()
    Dim i As Integer

    For i = Application.CommandBars("Ply").Controls.Count To 1 Step -1
        If Application.CommandBars("Ply").Controls(i).Caption = "&Insérer..." Then
            Application.CommandBars("Ply").Controls(i).Delete
        End If
    Next
End Sub
'Définition du nouveau menu insérer
Public Sub NouveauInserer()
    Set MainMenu = CommandBars("Ply").Controls.Add(Type:=msoControlButton, Before:=1, temporary:=True)
        With MainMenu
            .Caption = "&Insérer une nouvelle feuille"   'Texte affiché
            .OnAction = "AjouterUneFeuille"       'Nom de la macro
        End With
End Sub

'Retourne le menu à la normale
Public Sub RetourNormale()
    Application.CommandBars("Ply").Reset
End Sub

'Ajoute une nouvelle feuille
Public Sub AjouterUneFeuille()
    Sheets.Add
End Sub

et il faut placer ceci dans ThisWorkBook

'Active le menu à l'ouverture
Private Sub Workbook_Open()
    RetourNormale
    MiseEnPlace
End Sub

'Reset le menu
Private Sub Workbook_BeforeClose(Cancel As Boolean)
    RetourNormale
End Sub

'Quand on change de classeur, reset le menu
Private Sub Workbook_Deactivate()
    RetourNormale
End Sub

'Quand on revient dans le classeur, active le menu
Private Sub Workbook_Activate()
    RetourNormale
    MiseEnPlace
End Sub

voici mon fichier test si tu veux le consulter:

https://www.excel-pratique.com/~files/doc2/TestMenuInserer.xls

Si t'as des questions hésite pas

Bonsoir Math

Merci bien pour ta réponse. ça résoud mon problème

Salut le forum

Drdidji et ceci aussi résouds ton problème....

• Dès que votre problème est résolu, merci de le marquer en tant que [Résolu]
  grâce à l'utilitaire se trouvant en bas de page, aperçu :

Mytå