Pb application d'un code VBA

Bonjour,

J'ai trouvé par hasard un Code VBA qui permet de surligner en jaune clair les lignes et colonnes actives, jusqu'au pointeur de la cellule.

d'après ce qui est dit il faudrait coller le code sur le module de code Worksheet. du gestionnaire d'évenment Worksheet_SelectionChange...

Mais je vois pas où le placer dans le Visual Basic Excel ??? car je ne connais pas l'utilisation des codes VBA.

Quelqu'un peut-il m'aider Svp ?

Bonsoir

Donne le code que je test car ton explicatiob est pas claire

Voici le Code :

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

Dim iColor As Integer

'// Remarque : ne pas utiliser si vous avez des mises en forme

'// conditionnelles que vous souhaitez conserver

'// On Error reprend si l'utilisateur sélectionne une plage de cellules

On Error Resume Next

iColor = Target.Interior.ColorIndex

'// Laisse On Error ACTIVÉ pour les erreurs de décalage de lignes

If iColor < 0 Then

iColor = 36

Else

iColor = iColor + 1

End If

'// Test nécessaire si la couleur de la police est la même

If iColor = Target.Font.ColorIndex Then iColor = iColor + 1

Cells.FormatConditions.Delete

'// Bande de couleur horizontale

With Range("A" & Target.Row, Target.Address) 'Rows(Target.Row)

.FormatConditions.Add Type:=2, Formula1:="TRUE"

.FormatConditions(1).Interior.ColorIndex = iColor

End With

'// Bande de couleur verticale

With Range(Target.Offset(1 - Target.Row, 0).Address & ":" & _

Target.Offset(-1, 0).Address) 'Rows(Target.Row)

.FormatConditions.Add Type:=2, Formula1:="TRUE"

.FormatConditions(1).Interior.ColorIndex = iColor

End With

End Sub

essaye juste de le placer dans un module normal

Pour cela tu ouvre visual basic (dans le menu des macros) et ensuite tu fais "nouveau module"...

Tu colles ton code.

Ensuite tu reviens dans ton classeur, outils/macro/executer ton code...

Merci pour cette réponse mais j'ai essayé et çà ne marche pas ...

Outils / Macro puis Visualbasic

Visualbasic

Insertion / Module (je colle mon code) puis je retourne au classeur

Exécuter Macro et rien ???

Doit manquer quelques choses ?

Salut le Forum

Callou ta macro ne fonctionne pas !

Ou l'as-tu trouvé ?

Mytå

Bonsoir Mytå,

C'est dans l'aide Online Microsoft

A+

Salut le forum

Callou le code va dans le module de la feuille et non dans un module standard.

Attention, si ta version excel est français, il faut remplacer TRUE par VRAI

Le fichier en pièce jointe pour version française. Le Fichier

Mytå

Merci Mytå,

J'utilise jamais les VBA, j'avais pas pensez à cliquer droit dans la Feuille1 en Macro

P.S. Finalement à y regarder, il me faudrait plus une barre de "Scroll horizontal" pour surligner les cellules en cours sans la colonne. Mais belle effet tout de même.

Salut le forum

Si tu veux juste la ligne, le code

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim iColor As Integer

'// Remarque : ne pas utiliser si vous avez des mises en forme
'// conditionnelles que vous souhaitez conserver

'// On Error reprend si l'utilisateur sélectionne une plage de cellules
On Error Resume Next
iColor = Target.Interior.ColorIndex

'// Laisse On Error ACTIVÉ pour les erreurs de décalage de lignes
If iColor < 0 Then
    iColor = 36
Else
    iColor = iColor + 1
End If

'// Test nécessaire si la couleur de la police est la même
If iColor = Target.Font.ColorIndex Then iColor = iColor + 1
Cells.FormatConditions.Delete

'// Bande de couleur horizontale
With Rows(Target.Row)
    .FormatConditions.Add Type:=2, Formula1:="VRAI"
    '***Remplacer VRAI par TRUE si version anglaise
    .FormatConditions(1).Interior.ColorIndex = iColor
End With

End Sub

Mytå

Merci Mytå ,

Tu as raison comme c'était marqué dans les ligne infos, il suffisait de supprimer le paragraphe. Impec.

A+