Validation données-> numérique+1 lettre+décimal
Bonjour,
J'aimerai utiliser la validation de donnée pour ne permettre que des chiffres et 1 lettre
Idéalement "numérique+ 1 lettre+décimal"
Exemple : 100x2,9
Là j'avoue que je n'ai aucune idée de départ. Auriez-vous une astuce?
Merci d'avance
Patrick
bonjour Patrick
une piste
dans la fenêtre Validation des données, choisir Autoriser Personnaliser
j'ai mis
=ESTNUM(A2)
dès lors on ne peut saisir que des nombres en A2
étendre cette validation en "tirant" la cellule vers le bas
tu sauras construire une formule qui teste la forme de ta saisie
tu vas manger quelques fonctions de texte
Salut jmd,
Le début me parait bien bien claire.
Par contre la seconde partie
tu sauras construire une formule qui teste la forme de ta saisie
tu vas manger quelques fonctions de texte
???
Le plus dure étant la suite
Bonsoir Patrick,
J'sais pas pourquoi, kek'chose me dit qu'ta lettre est toujours un « x », pas vrai ? du genre : largeur × hauteur
alors sauf si j'me suis trompé, j'te propose d'essayer cette large longue formule de validation de données :
=SIERREUR(TROUVE("x";A1);0)*ESTNUM(--GAUCHE(A1;CHERCHE("x";A1)-1))*ESTNUM(--DROITE(A1;NBCAR(A1)-CHERCHE("x";A1)))>0
⚠ Seule la lettre x minuscule est autorisée : pas de X majuscule, ni aucune autre lettre !
Merci d'me donner ton avis (y compris si j'me suis trompé !
dhany
Bonjour Dhany,
C'est exactement ça !!! Merci !!!
Je viens de comprendre pourquoi "jmd" avait mis en exemple =ESTNUM
Dans la formule de validation personnalisé il faut un retour de type booléen !!!
Après j'ai essayé de comprendre ta formule.
1) Tu testes si la cellule contient "x" et retournes sa position. 0 dans le cas contraire.
2) Tu cherches la position du "x" depuis la gauche et la droite pour supprimer le reste et tester si c'est une valeur numérique.
3) Tu multiplies le tout pour savoir si c'est >0 et créer ainsi la valeur booléenne VRAI/FAUX.
Je ne savais pas que tu pouvais utiliser les valeurs VRAI/FAUX dans des calculs
C'est quoi les - - GAUCHE - - DROITE ?
Bonjour Patrick,
Tu a écrit :C'est quoi les - - GAUCHE - - DROITE ?
En A1 (par exemple) : 100x2,9
GAUCHE(A1;CHERCHE("x";A1)-1) retourne la partie gauche de A1 qui est juste avant le x : 100 ; mais ce retour de la fonction GAUCHE() est du texte : ce sont juste 3 caractères "100" ; avec un seul moins devant, c'est converti en nombre : -100 ; le double moins est pour qu'il conserve son signe positif : --100 = +100 = 100 ; pour --DROITE() qui retourne le texte "2,9", c'est la même chose.
rappel : la conversion en nombre est nécessaire pour le test ESTNUM()
dhany
OK super, il me semblait bien que c'était ça, mais cela faisait bizarre d'en avoir deux devant une fonction.
PS. Cela fonctionne aussi avec 1 seul minus - . Car -2 * -2 =4
Dans tous les cas, merci
Et moi j'ai encore du boulot car je dois aussi autoriser des nombres décimales seuls, et ne pas permettre d'espaces.
A+
Patrick
Tu a écrit :je dois aussi autoriser des nombres décimals seuls, et ne pas permettre d'espaces
1) Pour vérifier si c'est un décimal ou non, voici une piste :
En A1 : 50,01 ; en B1 : =--(A1<>ENT(A1)) ➯ 1
en A2 : 50 ; en B2 : =--(A2<>ENT(A2)) ➯ 0
2) Pour supprimer les espaces :
a) qui sont en début de chaîne ou en fin de chaîne (et réduire ceux du milieu) :
En A4 : " abc def ghi " (ne pas taper les guillemets, et chaque blanc = 5 espaces)
en A5 : ="(" & SUPPRESPACE(A4) & ")" ➯ (abc def ghi)
* L'ajout des 2 parenthèses est pour vérifier qu'il n'y a pas d'espaces entre ( et a ; ni entre i et )
* Les 2 blancs de 5 espaces au milieu de la chaîne ont été réduits à un seul espace
* Après la vérif, ne pas oublier d'enlever les parenthèses
b) qui sont en début de chaîne, en fin de chaîne, et aussi au milieu :
En A4 : laisser tel que c'est actuellement (même chose que ci-dessus)
En A6 : ="(" & SUBSTITUE(A4;" ";"") & ")" ➯ (abcdefghi)
reste à intégrer tout ça (avec adaptation) à la déjà bien longue formule de validation de données !
bon courage !!!
dhany