Remise a zero de plusieurs colonnes

Bonjour le forum

Dans le fichier que j ai trouver sur le net

je veux rajouter des colonnes a remettre a zéro

Dans la macro j ai mis en rouge les lignes que j ai rajouter pour la feuille Série

quand je déclenche la macro celle ci efface que les colonnes U3:V

et n efface pas les colonnes C3:F , I3:J , M3:N

quelle erreur j ai fait et comment la modifier

Sub Raz()
Dim DerLigne_Equipe As Integer
Dim Msg As Integer

'Détermination du N°de la dernière ligne
  DerLigne_Equipe = Sheets("Equipes").Range("C3").End(xlDown).Row

' Avertissement avant effacement données
Msg = MsgBox("Cette procédure va effacer toutes les données du concours. Voulez-vous continuer?", vbYesNo + vbDefaultButton2, "Concours de belote: Remise à zéro des données ")
If Msg = vbNo Then
Exit Sub
End If
If Msg = vbYes Then
GoTo suite:
End If

'sélection et efface données
suite:
    Sheets("Equipes").Select
    Range("C3:G" & DerLigne_Equipe).Select
    Selection.ClearContents
    Range("C1").Value = 0

    Sheets("Séries").Select
    Range("C3:F" & DerLigne_Equipe).Select
    Range("I3:J" & DerLigne_Equipe).Select
    Range("M3:N" & DerLigne_Equipe).Select
    Range("U3:V" & DerLigne_Equipe).Select
    Selection.ClearContents
    Range("A1").Select

    Sheets("Classement").Select
    Range("A2:D" & DerLigne_Equipe).Select
    Selection.ClearContents
    Range("A2").Select

Cmd_UsfAccueilSortir = 0

End Sub

merci d avance

Cordialement

Wazizou

Bonjour Wazizou

Tu voudras bien réediter ton post pour bien mettre le code entre balises STP

Ton erreur est que tu sélectionnais des plages, sans rien faire derrière, ensuite, tu n'as pas besoin de faire des SELECT pour appliquer une action

Sub Raz()
  Dim DerLigne_Equipe As Integer
  Dim Msg As Integer
  'Détermination du N°de la dernière ligne
  DerLigne_Equipe = Sheets("Equipes").Range("C3").End(xlDown).Row
  ' Avertissement avant effacement données
  If MsgBox("Cette procédure va effacer toutes les données du concours. Voulez-vous continuer?", _
            vbYesNo + vbDefaultButton2, "Concours de belote: Remise à zéro des données ") = vbNo Then Exit Sub

  ' Effacement des données
  ' Avec la feuille Equipes
  With Sheets("Equipes")
    .Range("C3:G" & DerLigne_Equipe).ClearContents
    .Range("C1").Value = 0
  End With
  ' Avec la feuille Séries
  With Sheets("Séries")
    .Range("C3:F" & DerLigne_Equipe).ClearContents
    .Range("I3:J" & DerLigne_Equipe).ClearContents
    .Range("M3:N" & DerLigne_Equipe).ClearContents
    .Range("U3:V" & DerLigne_Equipe).ClearContents
  End With
  ' Avec la feuille classement
  With Sheets("Classement")
    .Range("A2:D" & DerLigne_Equipe).ClearContents
  End With
  Cmd_UsfAccueilSortir = 0
End Sub

Voilà

Bonjour BrunoM45 et le forum

merci pour ton aide cela fonction

je viens de rééditer mon post

merci pour les conseils

bonne journée

Cordialement

Wazizou