Tri une ligne sur deux

Bonjour tout le monde,

J'ai un fichier texte à la base que j'importe dans Excel et le résultat me donne quelques soucis pour le formater...

Sur la ligne 1 j'ai le nom d'un PC et sur la ligne 2 j'ai la version de son Windows.

J'aurais voulu réorganiser tout ça en mettant la ligne 1 sur une nouvelle colonne et son Windows dans une autre colonne.

Donc en visuel j'ai ça :

PC1

Windows7

PC2

Windows10

PC3

Windows

Et je voudrais à partir de ces datas avoir :

PC1 Windows7

PC2 Windows10

PC3 Windows

2 colonnes au final quoi

Si vous aviez l'extreme gentillesse vous me souveriez un temps de dingue !!

Merciii

Bonjour Tessai.

Sans fichier c'est difficile de savoir comment est composée ta feuille.

En estimant que ta première ligne commence en [A1], tu peux utiliser ce code :

Sub transpose()
Dim temp(), a(), i&, n&
With Sheets(1)
temp = .[a1].CurrentRegion.Value
ReDim a(1 To UBound(temp), 1 To 2)
For i = 1 To UBound(temp) Step 2
    n = n + 1
    a(n, 1) = temp(i, 1)
    a(n, 2) = temp(i + 1, 1)
Next i
.[a1].CurrentRegion.Clear
.[a1].Resize(UBound(a), 2).Value = a
End With
End Sub

ça fonctionne nickel, quelle rapidité, quel talent !!

Merci !!!

Bonjour,

Benoît a été plus rapide !

Sub Test()
    Dim n%, i%, Tbl()
    With ActiveSheet
        n = .Cells(.Rows.Count, 1).End(xlUp).Row
        If n Mod 2 = 1 Then n = n + 1
        ReDim Tbl(1 To n / 2, 1)
        For i = 2 To n Step 2
            Tbl(i / 2, 0) = .Cells(i - 1, 1)
            Tbl(i / 2, 1) = .Cells(i, 1)
        Next i
        Application.ScreenUpdating = False
        With .Cells(1, 1)
            .Resize(n).ClearContents
            .Resize(n / 2, 2).Value = Tbl
        End With
    End With
End Sub

Solution quasi-identique dans son principe, juste le style qui diffère un peu... Tir groupé !

Cordialement.

Bonjour @ tous !

a été plus rapide !

C'est rare... mais ça arrive ! Cela vous rend "plus humain" !

@ bientôt

LoureeD

LouReeD a écrit :

Bonjour @ tous !

a été plus rapide !

C'est rare... mais ça arrive ! Cela vous rend "plus humain" !

@ bientôt

LoureeD

J'ai eu de la "chance" de voir le post avant je pense

Hum ! Je suis plutôt lent... donc "très humain" si je comprends bien !