Ouvrir un fichier Xls en masquant

Hello à tous

Petit mystère sur le sujet de mon topic

Je vous explique.

Est-il possible à l'ouverture d'un fichier xls bien spécifique de masquer la barre de formule et le ruban?

D'avance merci.

Bonjour Nowhereman,

Ce code VBA est pour masquer / afficher ruban & barre de formule (alternativement, une fois sur deux) :

Sub Essai()
  With Application
    If .DisplayFormulaBar Then
      .DisplayFormulaBar = False
      If .CommandBars("Ribbon").Height > 100 Then SendKeys "^{F1}"
    Else
      .DisplayFormulaBar = True
      If .CommandBars("Ribbon").Height < 100 Then SendKeys "^{F1}"
    End If
  End With
End Sub

Pour masquer automatiquement ruban & barre de formule à l'ouverture du classeur, mettre dans ThisWorkbook :

Private Sub Workbook_Open()
  With Application
    If .CommandBars("Ribbon").Height > 100 Then SendKeys "^{F1}"
    .DisplayFormulaBar = False
  End With
End Sub

(ceci à la place du code VBA précédent, pas en plus)

Cordialement

Bonjour,

Une autre piste :

Sub Test()

    Dim Afficher As String

    Afficher = "True" ' ou "False"

    Application.ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon""," & Afficher & ")"
    Application.DisplayFormulaBar = CBool(Afficher)

End Sub

Hello à tous,

Aucunes des deux solutions ne fonctionnent.

Je vous mets le fichier en pièce jointe pour vous aider si vous voulez tjs me venir en aide

Merci

Je te retourne ton fichier modifié :

À l'ouverture : ruban & barre de formule sont masqués ;

regarde le code VBA qui est dans ThisWorkbook.

Bonjour,

Dans ton module ThisWorkbook ...

Option Explicit

Private Sub Workbook_Open()
    Application.ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon"",False)"
    Application.DisplayFormulaBar = False
    Application.DisplayStatusBar = Not Application.DisplayStatusBar
    ActiveWindow.DisplayWorkbookTabs = False
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    Application.ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon"",True)"
    Application.DisplayFormulaBar = True
    Application.DisplayStatusBar = True
    ActiveWindow.DisplayWorkbookTabs = True
End Sub

Private Sub Workbook_Activate()
    Application.ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon"",False)"
    Application.DisplayFormulaBar = False
    Application.DisplayStatusBar = Not Application.DisplayStatusBar
    ActiveWindow.DisplayWorkbookTabs = False
End Sub

Private Sub Workbook_Deactivate()
    Application.ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon"",True)"
    Application.DisplayFormulaBar = True
    Application.DisplayStatusBar = True
    ActiveWindow.DisplayWorkbookTabs = True
End Sub

En espèrant que cela t'aide

Merci, ça fonctionne!

Parfait ! merci d'avoir passé le sujet en résolu.

Bonsoir à toutes et tous,

Une proposition issue du lien ci-dessous.

Il faut préalablement ajouter 'Masquer le ruban' à la barre d'outils Accès rapide.

https://stackoverflow.com/questions/39201757/vba-auto-hide-ribbon-in-excel-2013

Cdlt.

Private Sub Workbook_Open()
    With Application
        .CommandBars.ExecuteMso ("HideRibbon")
        .DisplayFormulaBar = False
    End With
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    Application.DisplayFormulaBar = True
End Sub

Salut Jean-Eric ...

Il faut préalablement ajouter 'Masquer le ruban' à la barre d'outils Accès rapide.

Comme toujours ... ta suggestion est plus que pertinente ... ... elle est même très adéQAT ... !!!