Problème enregistrement CSV

Bonjour à tous,

Je souhaiterais savoir si il est poossible d'enregistrer un fichier excel en CSV sans que des guillements apparaissent dans le fichier csv.

Exemple dans une cellule d'une fichier excel j'ai : Test

et lors de l'enregistrement au format csv ça me donne : "Test"

Or je souhaiterais obtenir le format : Test

Auriez vous une solution svp ?

Merci pour votre aide,

Cordialement

Bonjour,

Ta question m'a fait creuser dans mes archives ...

Tu peux tester le code suivant :

Sub SauverCSV()
' author: Damon Ostrander - 08 Avril 2006
' Sauvegarder au format CSV sans les guillemets '''''''''''''
Dim Rec As String
Dim FileNo As Integer
Dim FileName As Variant
Dim iRow As Long
Dim iCol As Integer
Dim MaxRow As Long
Dim MaxCol As Integer

FileName = ActiveWorkbook.Name
  If FileName Like "*.????" Then
    FileName = Left(FileName, Len(FileName) - 5) & ".csv"
  End If

FileName = Application.GetSaveAsFilename(FileName, "CSV/text files (*.csv;*.txt),*.csv;*.txt", _
1, "Save As CSV file")

If FileName = False Then Exit Sub

FileNo = FreeFile
Open FileName For Binary Access Write As FileNo

  With ActiveSheet.UsedRange
    For iRow = 1 To .Row + .Rows.Count - 1
        For iCol = 1 To Cells(iRow, 256).End(xlToLeft).Column
          If iCol = 1 Then
            Rec = Cells(iRow, iCol).Text
          Else
            Rec = Rec & "," & Cells(iRow, iCol).Text
          End If
        Next iCol
      Put FileNo, , Rec & vbCrLf
    Next iRow
  End With

Close FileNo
End Sub

J'espère que cela pourra t'aider ...

Tout d'abord merci pour ta réponse car cela fonctionne parfaitement,

mais est-il possible de l'adapter à ce type de syntaxe :

ActiveWorkbook.SaveAs Filename:=Cheminfichiersortie & "\" & nomfichiersortie, FileFormat:=xlCSV, CreateBackup:=False, local:=True

car ici : ActiveWorkbook.SaveAs Filename = Application.GetSaveAsFilename(nomfichiersortie, "CSV/text files (*.csv;*.txt),*.csv;*.txt", _

1, "Save As CSV file")

je ne peux pas choisir le chemin et l'enregistrement se fait de maniere manuelle ( je dois cliquer sur enregistrer et choisir le chemin)

Merci pour votre réponse!

Re,

Content que la solution fonctionne ...

Si tu as redéfini toutes tes variables ... je ne vais pas pouvoir deviner ce que tu as fait ...

Cela dit pour ta question, tu peux t'inspirer de la structure suivante :

ActiveWorkbook.SaveAs "C:\" & Cheminfichiersortie & "\" & FileName

J'espère que cela va t'aider ...