Vérifier ID code correspondant, selon tableau identificat

Bonjour,

Voudriez-vous m'aider, s'il vous plaît, à vérifier que dans un userform avec un combobox qui fait choisir le nom à l'utilisateur, puis qui demande d'entrer le code correspondant dans un textbox, que le code est correct, sinon refusé ? Les codes se trouvent sur la colonne suivant celle des noms, dans une feuille Excel.

Quel est le code VBA pour qu'il y ait au clic sur OK, une comparaison avec le code ID correspondant au nom renseigné ?

Toute aide est bienvenue.

Merci d'avance.

Xav.

Private Sub OKID_Click()
If Professeur.Value <> "" Then          'si la Combobox1 n'est pas vide, alors on continue la procédure
     Else                               'sinon
MsgBox "Veuillez renseigner votre ID (nom et prénom)"   'affichage de ce Msgbox
     Exit Sub                           'on sort de la procédure, donc on inscrit rien
     End If                             'fin de la condition
     If Code.Value <> "" Then
     Else
MsgBox "Veuillez renseigner votre Code personnel"
     Exit Sub
     End If
If '(Recherche de solution pour compléter le code)
End Sub

Bonjour,

Une piste mais il y en a plusieurs :

Private Sub OKID_Click()

    Dim Plage As Range
    Dim Cel As Range

    If Professeur.Text = "" Then MsgBox "Veuillez renseigner votre identifiant (nom et prénom)", vbExclamation: Exit Sub

    If Code.Text = "" Then MsgBox "Veuillez renseigner votre Code personnel", vbExclamation: Exit Sub

    'la plage est définie en colonne A de la feuille "Feuil1" à partir de A1, à adapter...
    With Worksheets("Feuil1"): Set Plage = .Range(.Cells(1, 1), .Cells(.Rows.Count, 1).End(xlUp)): End With

    'effectue la recherche exacte
    Set Cel = Plage.Find(Professeur.Text, , xlValues, xlWhole)

    'si pas trouvé, message et fin
    If Cel Is Nothing Then MsgBox "Identifiant mal orthographié ou inexistant !", vbExclamation: Exit Sub

    'si trouvé mais que le code situé en colonne B sur la même ligne est faux, message et fin
    If Cel.Offset(, 1).Value <> Code.Text Then MsgBox "Le code saisi ne correspond pas à l'identifiant !": Exit Sub

    'à partir d'ici, ton code...
    MsgBox "Bravo !" & vbCrLf & vbCrLf & "Vous avez franchi la super protection ;-)", vbInformation

End Sub

Salut Theze,

Merci pour ta réponse et ta réaction rapide : TU AS RÉSOLU MON PROBLEME !

Xav.