Recopie formule avec espace de 7 cellules
Bonjour ,
j ai besoin d aide !
je dois incorporer dans la formule ci dessous (qui se trouve dans ma feuille production !)
=SI('SAISIE DE CDE'!N2="";0;ARRONDI.INF(('SAISIE DE CDE'!$J2*'SAISIE DE CDE'!O2)/8;0))
un argument afin de recopier ma formule de haut en bas mais en decalant de 7 cellules...
Feuille 1 = Saisie de cde
Feuille 2 = production
je pense que je dois incoporer cette formule (ligne()-3)*7+2)
mais je ne sais pas ou ????
Apparament ma formule contient trop d element !!!!
un grand merci pour les reponses !!!!!
Bonjour
Je pense que tu devras utiliser la fonction DECALER
Regarde joindre un fichier, en haut de cette page et envoie un bout de fichier sur le forum
Cordialement
Bonjour,
Peut-être un essai avec cette formule :
=SI(MOD(LIGNE()-3;7)=0;SI('SAISIE DE CDE'!N2="";0;ARRONDI.INF(('SAISIE DE CDE'!$J2*'SAISIE DE CDE'!O2)/8;0));"")Je te laisse tester
@+
Edit : Bing ! Salut Amadeus
@+
je n arrive pas a telecharger mon fichier trop lourd !!!
voici ce que je souhaite faire
L3 =
SI('SAISIE DE CDE'!N2="";0;ARRONDI.INF(('SAISIE DE CDE'!$J2*'SAISIE DE CDE'!O2)/8;0))
et je souhaite que
L4 =SI('SAISIE DE CDE'!N9="";0;ARRONDI.INF(('SAISIE DE CDE'!$J9*'SAISIE DE CDE'!O9)/8;0))
L5 = SI('SAISIE DE CDE'!N16="";0;ARRONDI.INF(('SAISIE DE CDE'!$J16*'SAISIE DE CDE'!O16)/8;0))
a savoir que L3.L4.L5 ds feuille production
et 1ere feuille saisie de cde !
je nn arrive pas recopier la formule en ajoutant 7 cellule d ecart !!!
a moins de changer ds la formule a chaque fois le nom des cellules !
avez vous une solution plus pratique ????
merci mercii !!!! je deviens folle
re,
Ca devient un peu plus clair.
En se servant de la formule que tu proposais au départ, en L3 :
=SI('SAISIE DE CDE'!N2="";0;ARRONDI.INF((DECALER('SAISIE DE CDE'!$J2;(LIGNE()-3)*7;)*DECALER('SAISIE DE CDE'!O2;(LIGNE()-3)*7;))/8;0))à recopier vers le bas
Je te laisse tester
On pouvait également envisager une solution avec INDEX
@+
Bonjour, salut thibo
Thibo:
1) pour que ta formule fonctionne, il te faut mettre les $ pour bloquer ($J$2 et $O$2)
2) Tu n'as pas incrémenté la première condition SI
Correction:
=SI(DECALER('SAISIE DE CDE'!$N$2;(LIGNE()-3)*7;)="";0;ARRONDI.INF((DECALER('SAISIE DE CDE'!$J$2;(LIGNE()-3)*7;)*DECALER('SAISIE DE CDE'!$O$2;(LIGNE()-3)*7;))/8;0))
Autre formule
en L3, tu pourrais aussi tester
=SI(INDIRECT("'SAISIE DE CDE'!N"&(LIGNE()-3)*7+2)="";0;ARRONDI.INF((INDIRECT("'SAISIE DE CDE'!$J"&(LIGNE()-3)*7+2)*INDIRECT("'SAISIE DE CDE'!O"&(LIGNE()-3)*7+2))/8;0))
Cordialement