Envoyer une feuille

Question

J'ai besoin de votre aide, Je souhaiterai envoyer une feuille (active) dans un classeur par mail J'ai trouvé dans les options, une commande "envoyer par message", mais tout le classeur est en pièce jointe? J'ai inséré cette commande dans l'accès rapide. je crois savoir qu'il existe une commande dans les options (toutes les commandes) d'excel qui permet cet envoi Mais je ne la trouve pas Etant NOVICE, ne me demandez pas de créer une macro ou autre MERCI A TOUS...

jmd · Answer

Ma suggestion sans prise de tête : scinder ton fichier un fichier d'une feuille que tu peux envoyer les autres feuilles sont dans un autre fichier entre les 2, tu fais des liaisons...

jmd · Answer

VBA serait moins complexe que de créer une feuille

on essaye :

dans un répertoire Windows, mets ton fichier A qui possède 20 feuilles.
crée une copie de A, que tu appelles Abis
dans Abis supprime les feuilles de 2 à 20. Tu obtiens le fichier avec une unique feuille que tu peux envoyer.
dans A, supprime la feuille 1
dans A corrige les formules qui le nécessitent pour qu'elles viennent chercher les données dans Abis.

Zohnya · Answer

Https://forum.excel-pratique.com/excel/envoyer-le-contenu-d-une-feuille-par-email-t21321.html Cordialement...

Zohnya · Answer

Hello, voilà le code (en majeur partie tiré de la documentation Microsoft)

Sub Mail_ActiveSheet()
' Fonctionne avec Excel 2000, Excel 2002, Excel 2003, Excel 2007, Excel 2010, Outlook 2000, Outlook 2002, Outlook 2003, Outlook 2007, Outlook 2010
    Dim FileExtStr As String
    Dim FileFormatNum As Long
    Dim Sourcewb As Workbook
    Dim Destwb As Workbook
    Dim TempFilePath As String
    Dim TempFileName As String
    Dim OutApp As Object
    Dim OutMail As Object

    With Application
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    Set Sourcewb = ActiveWorkbook
    ActiveSheet.Copy
    Set Destwb = ActiveWorkbook

    With Destwb
        If Val(Application.Version) < 12 Then
            FileExtStr = ".xls": FileFormatNum = -4143
        Else
            If Sourcewb.Name = .Name Then
                With Application
                    .ScreenUpdating = True
                    .EnableEvents = True
                End With
                MsgBox "You answered NO in the security dialog."
                Exit Sub
            Else
                Select Case Sourcewb.FileFormat
                Case 51: FileExtStr = ".xlsx": FileFormatNum = 51
                Case 52:
                    If .HasVBProject Then
                        FileExtStr = ".xlsm": FileFormatNum = 52
                    Else
                        FileExtStr = ".xlsx": FileFormatNum = 51
                    End If
                Case 56: FileExtStr = ".xls": FileFormatNum = 56
                Case Else: FileExtStr = ".xlsb": FileFormatNum = 50
                End Select
            End If
        End If
    End With

    TempFilePath = Environ$("temp") & "\"
    TempFileName = "Part of " & Sourcewb.Name & " " _
                 & Format(Now, "dd-mmm-yy h-mm-ss")

    Set OutApp = CreateObject("Outlook.Application")

    Set OutMail = OutApp.CreateItem(0)

    With Destwb
        .SaveAs TempFilePath & TempFileName & FileExtStr, _
                FileFormat:=FileFormatNum
        On Error Resume Next
        With OutMail
            .To = ""
            .CC = ""
            .BCC = ""
            .Subject = ""
            .Body = ""
            .Attachments.Add Destwb.FullName
            .Display
        End With
        On Error GoTo 0
        .Close SaveChanges:=False
    End With
    Kill TempFilePath & TempFileName & FileExtStr

    Set OutMail = Nothing
    Set OutApp = Nothing

    With Application
        .ScreenUpdating = True
        .EnableEvents = True
    End With
End Sub

Pour assigner le bouton à une macro :

1. Se rendre dans l'onglet développeur

2. Selectionner le bouton "insérer" avec une petite valise.

3. Selectionner le bouton, et le créer (cliquer - glisser)

4. Clique droit sur le bouton

5. Selectionner "affecter une macro"

6. Créer une nouvelle macro

7. Coller le code que je t'ai donné.

Voilà.

Remarque est faite, que si tu désires de l'aide va valloir être un minimum sympathique. Ici les gens aident volontiers et le minimum c'est au moins de dire s'il te plait et pas de distribuer des ordres. ça donne vachement moins envie d'aider.

Cordialement

jmd · Answer

As-tu essayé ? non. Donc tu n'as pas pu constater que le découpage en 2 fichiers est à faire 1 unique fois. Maintenant. Et plus jamais par la suite ai-je un tempérament à faire 3 fois la même chose ...