Copier dans prochaine ligne disponible

Bonjour,

A l'aide du bouton "Terminer" de l'onglet "Entree" (voir le fichier ci-joint), je voudrais faire un "copier/coller - valeurs" dans l'onglet "Cumules_XXXXX, ou XXXXX est le numero de l'employe ("Entree!A3"). La source est dans l'onglet Cumules_00033, ligne 65 et la cible est la premiere ligne disponible a partir de la ligne 3, toujours dans le meme onglet. Selon mon exemple, la prochaine serait la ligne 4.

Merci d'avance de votre aide.

Quadat

Bonsoir Quadat, bonsoir le forum,

Je n'ai pas vu de bouton Terminer dans l'onglet Entree mais voici le code que tu pourras lui affecter :

Sub Macro1()
Dim OS As Worksheet 'déclare la variable OS (Onglet Source)
Dim NE As String 'déclare la variable NE (Numéro Employé)
Dim OT As Worksheet 'déclare la variable OT (Onglet de Travail)
Dim DEST As Range 'déclare la variable DEST (cellule de DESTination)

Set OS = Worksheets("Entree") 'définit l'onglet source OS
NE = CStr(Format(OS.Range("A3"), "00000")) 'définit le numéro d'employé NE
On Error Resume Next 'gestion des erreurs (en cas d'erreur passe à la ligne suivante)
Set OT = Worksheets("Cumules_" & NE) 'définit l'onglet de travail OT (génère une erreur si cet onglet n'existe pas)
If Err <> 0 Then 'condition : si une erreur a été générée
    MsgBox "Il n'y a pas d'onglet nommé [Cumules_" & NE & "] ! Opération avortée." 'Message
    Exit Sub 'sort de la procédure
End If 'fin de la condition
On Error GoTo 0 'annule la gestion des erreurs
'définit la cellule de destination DEST (A3, si A3 est vide, sinon la première cellule vide après A2)
Set DEST = IIf(OT.Range("A3").Value = "", OT.Range("A3"), OT.Range("A2").End(xlDown).Offset(1, 0))
OT.Rows(65).Copy 'copie la ligne 65 de l'onglet OT
DEST.PasteSpecial (xlPasteValues) 'colle les valeurs dans DEST
DEST.NumberFormat = "dd-mmm" 'formate la cellule DEST
End Sub

Beau travail ! Du premier coup ...

Je vais commencer avec cela car je peux avoir plusieurs employes dans l'onglet "Entree", mais ca fonctionne. Je te reviens si jamais j'ai un autre probleme.

Merci a toi !

Quadat