Lien dynamique entre deux feuilles de calcul

Bonjour à tous,

J'essaye de réaliser un petit outil de suivit de projet, et j'ai un soucis pour faire le lien et croiser des infos entre différentes feuilles de calculs.. je m'explique :

Dans la première feuille de calcul (tableau_entrées), j'ai un certain nombre de dossier avec des caractéristiques (dates de fin, responsable...). J'aimerais que quand je clique sur une affaire de la feuille 1 (par exemple A1), j'affiche dans la seconde feuille (tableau_sorties) un tableau qui synthétise les données pour cette affaire. Et si je choisis une autre affaire dans la feuille 1, le tableau de la feuille 2 se met à jour avec les données de la nouvelle affaire etc. J'imagine qu'il doit y avoir des macros spécifiques?

Mon descriptif est il assez clair ? je joins un classeur très simple en exemple de ce que je voudrai réaliser.

Merci d'avance pour votre aide, et à bientôt

Bonjour,

Essai à étudier :

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    Dim Tsort(), n%, i%, resp$
    On Error GoTo Fin
    If Not Intersect(Target, [Entrée]) Is Nothing Then
        On Error GoTo 0
        n = Target.Row - 1
        With [Entrée]
            resp = .Cells(n, 1)
            ReDim Tsort(1 To .Columns.Count - 2, 1 To 3)
            For i = 1 To UBound(Tsort, 1)
                Tsort(i, 1) = Replace(.Cells(0, i + 2), "date fin ", "")
                Tsort(i, 2) = resp
                Tsort(i, 3) = .Cells(n, i + 2)
            Next i
        End With
        With Worksheets("tableau_sorties")
            .Range("A1").CurrentRegion.Offset(2).ClearContents
            .Range("A3").Resize(UBound(Tsort, 1), 3).Value = Tsort
            .Activate
        End With
        Cancel = True
    End If
Fin:
End Sub

Double-clic dans le tableau entrées, le tableau sortie est alimenté avec la ligne cliquée.

La base Entrées est nommée Entrée : nom dynamique en lignes et colonne (la base peut s'étendre dans les deux sens.

Noter que la 1re colonne de Sortie est alimentée par la ligne d'en-tête d'Entrée après enlèvement de "date fin ".

Cordialement.

Bonjour,

Merci de ton aide, ça me va nickel, je comprends bien la logique du code je vais pouvoir me débrouiller pour faire quelque chose de plus élaboré. Juste une dernière petite question, où je peux avoir accès au code dans le fichier exel pour pouvoir le modifier? Je n'arrive pas à le trouver..

Merci encore ,

Cordialement

Dans le module de la feuille 1, il s'agit d'une procédure évènementielle, lancée par un évènement survenant sur cette feuille.

Accès direct par clic droit sur l'onglet et Visualiser le code...

Cordialement.

Super, merci !

Cordialement