Dialogue Enregistrer Sous en contraignant le format

Bonjour,

J'aimerais pouvoir faire en sorte que la boîte de dialogue "Enregistrer Sous ..." puisse apparaître en contraignant notamment le format de fichier (CSVMSDOS).

Pour cela j'utilise la méthode suivante pour laquelle je ne trouve pas la syntaxe des arguments (s'il y a une astuce pour déclencher l'aide dans l'éditeur ça m'aiderait aussi) :

Application.Dialogs(xlDialogSaveAs).Show [arg1], [arg2] ...

Pourtant j'essaie des choses comme

arg1:="nom_fichier.csv, arg2:=FileFormat:=xlCSV 

Merci de votre aide.

Hello,

Il ne faut pas écrire arg1, c'est pour l'llustration, une proposition de gestion de boite de dialogue, avec les paramètres fichier csv ) :

Sub Utilisation_FileDialog_Sauvegarde()

    With Application.FileDialog(msoFileDialogSaveAs)      
        .InitialFileName = "Nom fichier" 'Définit un nom par défaut dans le champ "Nom de fichier".
        .FilterIndex = 21 'Définit le type de fichier par défaut(la valeur 21 Permet de spécifier les classeurs "csv dos")

        .Show 'Affiche la boîte de dialogue
        .Execute 'Enregistre une fois choisi où sauvegarder
    End With

End Sub

Sub Dump_Filters() 'option => récupérer la liste des types de filterindex
    Dim i As Integer
    ActiveSheet.Cells.Clear
    With Application.FileDialog(msoFileDialogSaveAs)
        For i = 1 To .Filters.Count
            Range("A1").Offset(i - 1, 0).Value = .Filters(i).Description
        Next
    End With
End Sub

et une variante peut être plus facile à comprendre trouvé sur le fofo :

Sub choixRepEtFichier()
Dim repertoire As String, nomFichier As String, extension As String
    repertoire = "C:\Users\WAARD\Desktop\Nouveau dossier\"
    nomFichier = "fichierTest"
    extension = ".csv"
    Application.Dialogs(xlDialogSaveAs).Show repertoire & nomFichier & extension
End Sub

Pour l'aide, le raccourci clavier est F1 dans l'éditeur vba, mais avec les version post 2010, l'aide est pas facile d'utilisation je trouve.