Problème TCD VBA

Question

Je vous explique mon problème : j'ai un code pour récuperer et ranger correctement un fichier csv. Une fois que le csv est trié je réalise plusieurs opérations dont une qui est la création d'un tableau croisé dynamique, et c'est ici que ça coince. Mon code a toujours fonctioné jusque ici, mais je dois traiter un csv qui est plus gros que d'habitude qui une fois trier me donne 71 000 lignes et 20 colonnes.... est ce que le problème est que la limite d'un TCD est atteinte ? Mon code erreur est "running time 13 type mismatch" et quand je debug ça m'indique que le problème apparait à la création du TCD. Quand je lance le pas à pas tout fonctionne bien jusqu'au tcd également. Je poste le code ou le problème apparait. Merci de votre aide...

Jean-Eric · Answer

Déclare tes variables Derligne et Derncol en Long au lieu de Integer. Cdlt...

Jean-Eric · Answer

Merci de joindre un fichier, ou l'intégralité de ta procédure, en utilisant la balise de code. Mais pas une image. Cdlt...

Jean-Eric · Answer

RE, Merci de joindre un fichier csv et un fichier excel pour le résultat escompté. Cdlt...

Jean-Eric · Answer

RE,

Une première proposition à étudier, de ce que j'ai compris.

La procédure ci-dessous doit être enregistré dans ton classeur de macros personnelles (Personal.xlsb).

Tu ouvres ton fichier csv et tu lances la procédure Extraction.

Le résultat sera equivalent au classeur joint.

A te relire.

Cdlt.

80test-1.xlsb (416.31 Ko)

Option Explicit

Public Sub Extraction()
Dim wb As Workbook
Dim wsCSV As Worksheet, wsPT As Worksheet
Dim lo As ListObject
Dim PTCache As PivotCache
Dim PT As PivotTable

    Application.ScreenUpdating = False

    Set wb = ActiveWorkbook
    Set wsCSV = wb.Worksheets(1)

    With wsCSV
        .Rows("1:3").Delete Shift:=xlUp
        .Columns("A:A").TextToColumns _
                Destination:=Range("A1"), _
                DataType:=xlDelimited, _
                TextQualifier:=xlDoubleQuote, _
                Semicolon:=True, _
                FieldInfo _
                :=Array(Array(1, 4), Array(2, 4), Array(3, 1), Array(4, 1), Array(5, 1), _
                        Array(6, 1), Array(7, 1), Array(8, 1)), _
                TrailingMinusNumbers:=True
        Set lo = .ListObjects.Add(xlSrcRange, .Cells(1).CurrentRegion, , xlYes)
        With lo
            .Name = "tbl_Données"
            .TableStyle = ""
            .ListColumns.Add
            .HeaderRowRange(.ListColumns.Count) = "TEMPS"
            .HeaderRowRange.EntireColumn.AutoFit
            With .ListColumns("TEMPS").DataBodyRange
                .Cells(1, 1).FormulaR1C1 = "=[@EndTime]-[@StartTime]"
                .NumberFormat = "[hh]:mm:ss"
            End With
        End With
    End With

    Application.DisplayAlerts = False
    On Error Resume Next
    wb.Worksheets("").Delete
    On Error GoTo 0
    Application.DisplayAlerts = True
    Set wsPT = wb.Worksheets.Add
    wsPT.Name = "exploitationdata"

    Set PTCache = wb.PivotCaches.Create(SourceType:=xlDatabase, SourceData:=lo.Range)
    Set PT = PTCache.CreatePivotTable(TableDestination:=wsPT.Cells(3, 1), TableName:="TCD_1")
    With PT
        .ManualUpdate = True
        .AddFields RowFields:=Array("EquipmentName", "TimeCategoryName", "State")
        With .PivotFields("TEMPS")
            .Orientation = xlDataField
            .Position = 1
            .Function = xlCount
            .NumberFormat = "#,##0"
            .Caption = "NB TEMPS"
        End With
        With .PivotFields("TEMPS")
            .Orientation = xlDataField
            .Position = 2
            .Function = xlSum
            .NumberFormat = "[hh]:mm:ss"
            .Caption = ChrW(931) & " TEMPS"
        End With
        .RowAxisLayout xlTabularRow
        .ManualUpdate = False
    End With

    Set PT = Nothing
    Set PTCache = Nothing
    Set lo = Nothing
    Set wsCSV = Nothing: Set wsPT = Nothing
    Set wb = Nothing

End Sub

Jean-Eric · Answer

Ou en es tu ? Cdlt...

jmd · Answer

Bonjour salut Jean-Eric nul besoin de VBA, Excel dispose de tout ce qu'il faut tu as un fichier FOE.csv (Fichier Origine obtenu par Export). Ce fichier, tu ne le modifies jamais ! Bien entendu chaque export le régénère en entier. il suffit de créer un nouveau fichier MIR.xlsx ouvre MIR, menu Données Externes Fichiers Texte dans la fenêtre choisis le séparateur du fichier .csv Valide MIR est donc un miroir du csv désormais, à chaque ouverture de MIR, Excel te pose la question "mettre à jour ?" Oui Le tour est joué ATTENTION : il faut parfois figer la ligne 1 (les titres) dans MIR tu peux ajouter des colonnes (à droite pour ne pas gêner les mises à jour). On a souvent besoin de formules du genre =remettresousformededatespropres (lacolonnedesdatesmalexportées ) ou encore = quantité * prixunitaire ensuite, je te conseille de créer un FEX.xlsx (Fichier d'Exploitation) contenant des TCD, des formules, des SOMMEPROD qui lisent les valeurs dans MIR;xlsx simple, aucune macro. Excel pur...