Copier feuille VBA

Bonjours

Jai un fichier qui s'appelle "À " et qui comporte un onglet br-c

Jai en même temps d'ouvert une fichier "b" qui comporte aussi un onglet br-c

Je souhaite faire une macro qui me copie br-c de "à" sur br-c de "b"

Est ce que quelqu'un saurez comment faire car aucune solution sur le net ne marche

Bonjour,

A tester après avoir adapté :

Sub Test()

    Dim Classeur_A As Workbook
    Dim Classeur_B As Workbook
    Dim F_A As Worksheet
    Dim F_B As Worksheet
    Dim Plage As Range

    'adapter les noms des classeurs...
    Set Classeur_A = Workbooks("Classeur A.xlsm") '<--- classeur source
    Set Classeur_B = Workbooks("Classeur B.xlsm") '<--- classeur cible (devant recevoir les valeurs)

    'les noms des feuilles des deux classeurs étant identiques, sinon, adapter...
    Set F_A = Classeur_A.Worksheets("br-c")
    Set F_B = Classeur_B.Worksheets("br-c")

    'défini la plage sur toute la feuille
    Set Plage = DefPlage(F_A)

    'copie des données
    With F_B: .Range(.Cells(1, 1), .Cells(Plage.Rows.Count, Plage.Columns.Count)).Value = Plage.Value: End With

End Sub

Function DefPlage(Fe As Worksheet) As Range

    On Error GoTo Fin

    With Fe

        Set DefPlage = .Range(.Cells(1, 1), _
                       .Cells(.Cells.Find("*", .[A1], -4123, , _
                       1, 2).Row, .Cells.Find("*", .[A1], -4123, , _
                       2, 2).Column))

    End With

    Exit Function

Fin:

    Set DefPlage = Nothing

End Function