VBA copie les feuilles d'un autre classeur

bonjour

j'ai 2 classeurs et je souhaite à partir d'une macro du classeur A copier les feuilles du classeur B

voici donc ce que j'ai fait

Dim wkA As Workbook, wkB As Workbook

Dim chemin As String, fichier As String

'classeur A qui contient la macro

Set wkA = ThisWorkbook

'chemin ou se trouve le fichier B

chemin = "C:\"

'nom du fichier B

fichier = "test.xlsx"

'ouvre le fichier B

Workbooks.Open chemin & fichier

'met en variable le classeur B

Set wkB = ActiveWorkbook

For Each ws In Worksheets

wkB.Sheets(ws.Name).Copy After:=wkA.Sheets(Sheets.Count)

Next

sauf que j'ai une erreur

'9' l'indice n'appartient pas à la selection sur la ligne de copy

si une ame généreuse aurait une idée car mes recherches ne donnent rien

merci par avance

Bonjour,

Essais ceci :

Sub Test()

    Dim wkA As Workbook
    Dim wkB As Workbook
    Dim Ws As Worksheet
    Dim chemin As String
    Dim fichier As String

    'classeur A qui contient la macro
    Set wkA = ThisWorkbook

    'chemin ou se trouve le fichier B
    chemin = "C:\"

    'nom du fichier B
    fichier = "test.xlsx"

    If Dir(chemin & fichier) = "" Then Exit Sub

    'ouvre le fichier B
    Set wkB = Workbooks.Open(chemin & fichier)

    For Each Ws In wkB.Worksheets

        Ws.Copy , wkA.Sheets(wkA.Sheets.Count)

    Next

End Sub

ça marche ! merci beaucoup