Extraction tableau dans plusieurs feuilles

Bonjour à vous,

J'aimerai faire une extraction d'un tableau dans plusieurs feuilles différentes pour les lignes ayant la même valeur (voir exemple) mais je ne sais pas trop comment faire, pourriez vous m'aider?

Merci d'avance de votre aide.

Bonjour le forum,

Feuille A :

A2 :

=SI(LIGNE()-1>NB.SI(original!$A:$A;"A");"";INDEX(original!A:A;PETITE.VALEUR(SI(original!$A:$A="A";LIGNE(A:A);"");LIGNE()-1)))

Formule matricielle à valider avec CTRL MAJ ENTREE

Même formule dans les onglets B & C

(Remplacer les deux "A" par "B" ou "C".

Bonjour à tous,

Merci pour votre aide, en revanche j'aurai aimé quelque chose de plus automatique, en effet le tableau que j'ai à trier est vraiment gros et cette méthode bien que fonctionnant bien est très manuel.

smbd515 a écrit :

j'aurai aimé quelque chose de plus automatique, en effet le tableau que j'ai à trier est vraiment gros et cette méthode bien que fonctionnant bien est très manuel.

?????

Une minute pour la mise en place des formules dans les trois feuilles et ensuite gestion automatique des ajouts.

Bonjour,

Le problème est qu'il s'agit ici d'un exemple, dans mon vrai excel je n'ai pas 3 reférences mais 200, du coup cela prend un peu plus de temps à mettre en place.

Merci pour votre aide,

Bonjour à tous,

Sujet maintes fois abordé 8)

Vois ceci :

Option Explicit
Sub creation_feuilles()
    Dim rng As Range, i As Long, e
    Set rng = Sheets("original").Range("a1").CurrentRegion
    With CreateObject("Scripting.Dictionary")
        .CompareMode = 1
        For i = 2 To rng.Rows.Count
            If Not .exists(rng.Cells(i, 1).Value) Then
                Set .Item(rng.Cells(i, 1).Value) = _
                Union(rng.Rows(1), rng.Rows(i))
            Else
                Set .Item(rng.Cells(i, 1).Value) = _
                Union(.Item(rng.Cells(i, 1).Value), rng.Rows(i))
            End If
        Next
        For Each e In .keys
            If Not IsSheetExists(e) Then
                Sheets.Add(after:=Sheets(Sheets.Count)).Name = e
            End If
            Sheets(e).Cells(1).CurrentRegion.Clear
            .Item(e).Copy Sheets(e).Cells(1)
        Next
    End With
    Application.CutCopyMode = False
End Sub

Function IsSheetExists(ByVal sn As String) As Boolean
    On Error Resume Next
    IsSheetExists = Len(Sheets(sn).Name)
    On Error GoTo 0
End Function

klin89