Choix combobox2 en fonction combobox1

Bonjour,

j'aimerai avoir de l'aide pour d'une liste de lieu dans une usine, je n'ai qu'un certains nombre de personne,

c'est a dire si dans le lieu "y" il y a 4 personnes, dans le lieu "x" il y a 5 personnes

je ne souhaite pas avoir tout les noms des personnes si j'ai choisi un lieu

exemple il y a 25 et 5 lieu

si je choisi le lieu dans la combobox1 "a" j'ai que trois noms dans la combobox2

est ce que cela est possible? si oui je suis preneur pour apprendre.

Merci

Bonjour,

voici le document

Private Sub ComboBox1_Change()
    Dim lieu$, i%, n%
    ComboBox2.Clear
    If ComboBox1.ListIndex >= 0 Then
        lieu = ComboBox1.Value
        With Worksheets("Feuil1")
            n = .Cells(.Rows.Count, 1).End(xlUp).Row
            For i = 2 To n
                If .Cells(i, 1) = lieu Then ComboBox2.AddItem .Cells(i, 2)
            Next i
        End With
    End If
End Sub

Private Sub UserForm_Initialize()
    Dim d As Object, i%, n%
    Set d = CreateObject("Scripting.Dictionary")
    With Worksheets("Feuil1")
        n = .Cells(.Rows.Count, 1).End(xlUp).Row
        For i = 2 To n
            d(.Cells(i, 1).Value) = ""
        Next i
    End With
    ComboBox1.List = d.keys
End Sub

Cordialement.

supp

en essayant plusieurs changement j'ai réussi a l'adapter mon fichier

merci bien Mferrand

ton code ma super bien aidé.

je cloture donc le sujet.