Case à cocher et imprimer

Bonjour,

j'ai une feuille ou à la base je veux imprimer une section (C2:H25) mais j'ai également 6 cases à cocher ou j'aimerais que, dépendamment de la case (une ou plusieurs), les utilisateurs ait la possibilitée d'ajouter dans leur imprimé des sections qu'ils/elles jugent nécessaire. Donc pourrais s'ajouter à C2:H25 les sections suivantes

J34 est vrai ajouter C26:H28

J35 est Vrai ajouter C29:H31

J36 est vrai ajouter C32:H33

J37 est vrai ajouter C34:H35

J38 est vrai ajouter C36:H37

J39 est vrai ajouter C39:H41

Est-ce possible en macro considérant le nombre important de possibilités? Faut-il énumérer toutes les possibilités dans la macro ou il y a un moyen plus court d'accomplir le tout?

Merci encore de votre aide toujours précieuse pour un amateur comme moi!

Bonjour,

Une piste !

Tu pose sur ta feuille tes 6 "Cases à cocher" issues des contrôles "Formulaire" et pour chacune d'entre elle tu leur lie la cellule J34 pour la 1ère, J35 pour la seconde, etc... Pour ces six cellules, tu peux affecter un format personnalisé pour cacher les valeurs (VRAI ou FAUX) si tu le désires, le format est ;;; (3 points virgules). Attention tout de même, si les zones d'impression ne sont pas contigües elles seront sur des feuilles séparées. Si tu les veux sur la même feuille, il va falloir utiliser une autre feuille sur laquelle tu collera les valeurs choisies pour l'impression :

Sub DefinirZone()

    Dim Zone As String

    Zone = "C2:H25,"

    With ActiveSheet

        .PageSetup.PrintArea = ""

        If .Range("J34").Value = True Then Zone = Zone & "C26:H28,"
        If .Range("J35").Value = True Then Zone = Zone & "C29:H31,"
        If .Range("J36").Value = True Then Zone = Zone & "C32:H33,"
        If .Range("J37").Value = True Then Zone = Zone & "C34:H35,"
        If .Range("J38").Value = True Then Zone = Zone & "C36:H37,"
        If .Range("J39").Value = True Then Zone = Zone & "C39:H41,"

        Zone = Left(Zone, Len(Zone) - 1)

        .PageSetup.PrintArea = Zone

    End With

End Sub

Bonjour, j'ai copié la macro tel quel et je l'ai assigné à un bouton et rien ne se passe lorsque je l'exécute?

Pour voir le résultat, fais un aperçu avant impression !

Bonjour,

Je re-poste le code avec pour le test un aperçu avant impression et en dessous en commentaire la ligne d'ordre d'impression (enlever l'apostrophe devant et supprimer la ligne demandant l'aperçu avant impression) :

Sub DefinirZone()

    Dim Zone As String

    Zone = "C2:H25,"

    With ActiveSheet

        .PageSetup.PrintArea = ""

        If .Range("J34").Value = True Then Zone = Zone & "C26:H28,"
        If .Range("J35").Value = True Then Zone = Zone & "C29:H31,"
        If .Range("J36").Value = True Then Zone = Zone & "C32:H33,"
        If .Range("J37").Value = True Then Zone = Zone & "C34:H35,"
        If .Range("J38").Value = True Then Zone = Zone & "C36:H37,"
        If .Range("J39").Value = True Then Zone = Zone & "C39:H41,"

        Zone = Left(Zone, Len(Zone) - 1)

        .PageSetup.PrintArea = Zone

        .PrintPreview 'aperçu avant impression
        '.PrintOut 'impression

    End With

End Sub

Merci..je retest aussitôt que j'ai la chance et redonne des nouvelles

Finalement le travail à été abandonné et une autre direction est prise mais ca fonctionnais!

Merci encore!