Envoyer des données d'une feuille Excel par code VBA

Bonjour ,

comment envoyer des données d'une feuille Excel selectionner vers une table Access 2007 en utilisant code vba

merci d'avence

Bonjour,

Une piste. Adapte le chemin et nom de la base de données ainsi que le nom de la table visée. Le nombre de colonnes de la sélection doit correspondre au nombre de champs dans la base de même pour le type de valeurs (Date, Entier simple ou double, Long, Texte, etc...). Une fois adapté le chemin et nom de la table, effectue ta sélection dans ta feuille et lance la procédure "Ajouter" :

Private Sub ConnecterBase(ConnectBD As Object, Chemin As String, Optional Rs)

    Set ConnectBD = CreateObject("ADODB.Connection")

    If Not IsMissing(Rs) Then Set Rs = CreateObject("ADODB.Recordset")

    With ConnectBD

        .Provider = "Microsoft.Jet.OLEDB.4.0"
        .ConnectionString = Chemin
        .Open

    End With

End Sub

Sub Ajouter()

    Dim ConnectBDD As Object
    Dim Rs  As Object
    Dim NomBase As String
    Dim NomTable As String
    Dim Enrg As String
    Dim I As Integer
    Dim J As Integer
    Dim K As Integer

    NomBase = "G:\Dossiers 1\Dossier 2\NomDeLaBase.mdb"
    NomTable = "Nom_de_la_Table"

    ConnecterBase ConnectBDD, NomBase, Rs

    With Rs

        .CursorType = 1
        .LockType = 3
        .Open "SELECT * FROM " & NomTable, ConnectBDD

    End With

    For I = 1 To Selection.Rows.Count

        Rs.AddNew

        For J = 1 To Selection.Columns.Count

            Rs.Fields(K) = Selection.Cells(I, J).Value
            K = K + 1

        Next J

        Rs.Update

        K = 0

    Next I

    ConnectBDD.Close

    Set ConnectBDD = Nothing
    Set Rs = Nothing

End Sub

Merci de m'avoir répondu je vais essayer ce code

j'espère qu' il va marcher