Onglet résumé interactif

Bonjour,

Alors voila mon problème,

J'ai une classeur excel avec plusieurs onglet dedans et je souhaiterais faire un onglet qui résume les autres onglets.

Je voudrais que mon onglet 1 soit une copie des lignes (des autres onglets) pour lesquels il y à écrit "en cours" ou "en attente" ou "A signer" dans une certaine colonne.

Le plus serait que lorsque je change les valeurs sur l'onglet 1 sa change aussi les valeurs dans les onglet de bases.

Tout cela est il possible ou non ?

Merci de votre aide

Ci joint mon un exemple de mon classeur

Bonjour Reno, bonjour le forum,

Est-ce qu'une même pièce peut se trouver dans plusieurs onglets (sans compter le premier) ?

Bonjour,

Voilà pour la première partie :

Sub MajRésumé()
    Dim Tr(), etat, f%, n%, i%, e%, r%, k%
    etat = Split("En cours;En attente;A signer", ";")
    For f = 2 To Worksheets.Count
        With Worksheets(f)
            n = .Cells(.Rows.Count, 1).End(xlUp).Row
            For i = 2 To n
                For e = 0 To 2
                    If .Cells(i, 5) = etat(e) Then
                        r = r + 1: ReDim Preserve Tr(1 To 6, 1 To r): Tr(6, r) = f
                        For k = 1 To 5
                            Tr(k, r) = .Cells(i, k)
                        Next k
                    End If
                Next e
            Next i
        End With
    Next f
    With Worksheets(1)
        On Error Resume Next
        .Range("A2").Resize(.UsedRange.Rows.Count - 1, 6).ClearContents
        On Error GoTo 0
        .Range("A2").Resize(r, 6).Value = WorksheetFunction.Transpose(Tr)
    End With
End Sub

A tester.

La récupération en colonne F de l'index de la feuille d'origine est destinée à préparer la seconde partie (avoir une identification rapide de la feuille origine). Tu peux soit masquer la colonne F, soit mettre la couleur de police à blanc...

Pour la seconde partie, il serait bon de savoir si tes modifications n'affectent que la colonne E (Etat), ou peuvent affecter d'autres colonnes et lesquelles ?

Cordialement.

Bonjours,

Tout d'abord merci de vos réponses rapide.

Ensuite,

MFerrand: la modification affecte les colonnes c d et e

Votre première partie marche bien, seulement est t'il possible que cela se fasse automatiquement ? Sans que j'ai besoin d'exécuter la macro manuellement. Que le mise a jour se fasse tout seul des que je rajoute une ligne "en cours" dans les onglets (pas le premier).

ThauThème: non une pièce peut être que sur un onglet a la fois.

Bonjour,

Procédure à placer dans le module de Feuil1.

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim ref$, f%, k%, c As Range
    If Target.Count > 1 Then Exit Sub
    If Not Intersect(Target, Me.Columns("C:E")) Is Nothing Then
        ref = Me.Range("A" & Target.Row)
        f = Me.Range("F" & Target.Row): k = Target.Column
        With Worksheets(f)
            Set c = .Columns("A").Find(ref)
            If Not c Is Nothing Then c.Cells(1, k) = Target
        End With
    End If
End Sub

Cordialement.