Extraction de caractères

Bonjour,

Ma demande est simple et à la fois compliquée !

Voici ma demande :

J'ai les références article suivantes :

I-881310S Je cherche à extraire S

I-8315XL je cherche à extraire XL

I-15450XXL je cherche à extraire XXL

I-15451XXXL je cherche à extraire XXXL

450150STD je cherche à extraire STD

ST-4500STD je cherche à extraire STD

En fait je cherche à extraire la partie alphabétique finale de ma chaine de caractère.

Soit par une macro soit une formule.

Je joins un fichier excel pour exemple.

Merci par avance à celui ou celle qui pourra m'aider.

Bonjour Steph, bonjour le forum,

Peut-être comme ça :

Sub Macro1()
Dim O As Worksheet 'déclare la variable O (Onglet)
Dim DL As Integer 'déclare la variable DL (Dernière Ligne)
Dim V As String 'déclare la variable V (Valeur)

Set O = Worksheets("Feuil1") 'définit l'onglet O
DL = O.Range("A" & Application.Rows.Count).End(xlUp).Row 'définit la derniere ligne éditée DL de la colonne A de l'onglet O
For I = 2 To DL 'boucle 1 : des lignes I, de 2 à DL
    V = Cells(I, 1).Value 'définit la valeur V
    For Y = Len(V) To 1 Step -1 'boucle 2 : inversée, du dernier caractère de V au premier
        If IsNumeric(Mid(V, Y, 1)) Then 'condition si le caratère est numérique
            Cells(I, 2).Value = Right(Cells(I, 1).Value, Len(V) - Y) 'définit la valeur de la cellule adjacente en colonne 2 (=B)
            Exit For 'sort de la boucle 1
        End If 'fin de la condition
    Next Y 'prochain caractère de la boucle 2
Next I 'prochaine ligne de la boucle 1
End Sub

Bonjour

un essai : ctr+shift+E pour lancer la macro

fred

EDIT : Salut Thau Thème, les grands esprits se rencontre quasiment la même approche

Bonjour,

Autre solution : une fonction personnalisée.

Function EXTRACALPHAFIN(tx As String) As String
    Dim i%
    For i = Len(tx) To 1 Step -1
        If Mid(tx, i, 1) Like "#" Then Exit For
    Next i
    EXTRACALPHAFIN = Right(tx, Len(tx) - i)
End Function

Cordialement.

Bonjour à tous,

Merci pour les solutions trouvées !

Elles fonctionnent toutes bien, donc je n'ai pas su laquelle choisir donc je les prends toutes

donc bravo à tous et merci encore pour votre aide précieuse.

Bonne fin de journée

Stéphanie