Extraction des codes et les affectés au même cases

bonsoir ,

je tiens tout d'abord à remercier infiniment tous les gents qui nous aident toujours à résoudre nos problèmes en VBA

SVP, j'ai un problème au niveau d'une application que je viens de la concevoir , et j'ai besoin de votre aide parce que je ne maitrise pas trais bien VBA .

j'ai deux tableau ,un et dans la Feuil "base de données" et l 'autre dans la Feuil" les codes" ; j'ai besoin de remplir la colonne "code" dans la feuil "base de données " a partir de la Feuil " les codes " sans aucune suppression des doublons .vous trouvez le fichier Excel au dessous ,et merci d'avance

Bonsoir,

J'ai justement traité une question similaire il y a deux jours. Je n'ai eu qu'à changer les noms de feuilles et les numéros de colonnes...

Sub Coder()
    Dim d As Object, Cod(), n%, i%
    Set d = CreateObject("Scripting.Dictionary")
    With Worksheets("les codes")
        n = .Cells(.Rows.Count, 1).End(xlUp).Row
        For i = 2 To n
            d(.Cells(i, 1).Value) = .Cells(i, 2)
        Next i
    End With
    With Worksheets("base de données")
        n = .Cells(.Rows.Count, 1).End(xlUp).Row
        ReDim Cod(2 To n, 1 To 1)
        For i = 2 To n
            If d.exists(.Cells(i, 1).Value) Then Cod(i, 1) = d(.Cells(i, 1).Value)
        Next i
        .Cells(2, 2).Resize(n - 1).Value = Cod
    End With
End Sub

Cordialement.

merci beaucoup MFerrand ,ça marche très bien

bonjour ,

le code au dessus a bien fonctionné, mais il y a un petit problème c'est que si le nom d'élève est en majuscule dans la feuil " base de données " et en minuscule dans la feuil "les codes " ,le code de l'élève n'est pas affecté ,comment je fais pour que l 'affectation ne tiens pas en compte les majuscules et les minuscules ?? .vous trouvez le fichier au dessous ,merci d'avance

voici le code :

Sub Coder()
    Dim d As Object, Cod(), n%, i%
    Set d = CreateObject("Scripting.Dictionary")
    With Worksheets("les codes")
        n = .Cells(.Rows.Count, 1).End(xlUp).Row
        For i = 2 To n
            d(.Cells(i, 1).Value) = .Cells(i, 2)
        Next i
    End With
    With Worksheets("base de données")
        n = .Cells(.Rows.Count, 1).End(xlUp).Row
        ReDim Cod(2 To n, 1 To 1)
        For i = 2 To n
            If d.exists(.Cells(i, 1).Value) Then Cod(i, 1) = d(.Cells(i, 1).Value)
        Next i
        .Cells(2, 2).Resize(n - 1).Value = Cod
    End With
End Sub

En utilisant systématiquement des majuscules :

    [...]
        For i = 2 To n
            d(UCase(.Cells(i, 1).Value)) = .Cells(i, 2)
        Next i
    End With

    [...]

        For i = 2 To n
            If d.exists(UCase(.Cells(i, 1).Value)) Then Cod(i, 1) = d(UCase(.Cells(i, 1).Value))
        Next i
   [...]

Merci infiniment MFerrand