Valeurs les plus fréquentes dans une plage de cellules

Bonjour tout le monde,

J'ai à faire à une plage de cellules contenant une multitude de codes (chiffres et lettres) et je souhaiterais obtenir une liste des codes les plus fréquents (avec si possible leur fréquence).

J'ai tenté d'appliquer la formule MODE.MULTIPLE, mais en vain : #N/A ...

Etant débutante, un petit coup de pouce de votre part serait grandement apprécié !!!

Bonne soirée à vous,

Eliza

Bonjour,

Sub CodesFréquence()
    Dim d As Object, c As Range, n%, i%, j%, cd$, cod, frq
    Set d = CreateObject("Scripting.Dictionary")
    For Each c In ActiveSheet.UsedRange
        If c.Value <> "" Then
            If d.exists(c.Value) Then
                n = CInt(d(c.Value)) + 1: d(c.Value) = n
            Else
                d(c.Value) = 1
            End If
        End If
    Next c
    cod = d.keys: frq = d.items
    For i = LBound(frq) To UBound(frq)
        frq(i) = CInt(frq(i))
    Next i
    For i = LBound(frq) To UBound(frq) - 1
        For j = i + 1 To UBound(frq)
            If frq(j) > frq(i) Then
                n = frq(j): cd = cod(j)
                frq(j) = frq(i): cod(j) = cod(i)
                frq(i) = n: cod(i) = cd
            End If
        Next j
    Next i
    With Worksheets.Add
        .Range("A1").Resize(d.Count).Value = WorksheetFunction.Transpose(cod)
        .Range("B1").Resize(d.Count).Value = WorksheetFunction.Transpose(frq)
    End With
End Sub

Tu colles la macro ci-dessus dans ton classeur (dans un module standard). Tu la lances, ta feuille de codes étant la feuille active, et elle te listera tous les codes dans une nouvelle feuille par fréquence décroissante.

Cordialement.

Bonsoir Eliza & MFerrand,

Une autre proposition à tester.

2 propositions pour le prix d'une ! Les nouveaux entrants sont choyés

Bonne soirée

Bouben

Avec fréquence relative en plus ! Là, Bouben, c'est du luxe !

J'aime beaucoup les petits bonus qui prennent 1 minute et font leur effet.

Stratégie marketing du magnet offert dans la boîte de cordons bleus

Wahou quelle efficacité ! Un grand merci à vous !

Bon week-end et bonnes vacances pour ceux qui ont de la chance !