Remplissage cellules vides

Bonjour

Après import de données, il manque des infos essentielles en colonne B (feuille "Import")

La règle est la suivante : si cellule vide, elle prend la valeur de celle du dessus.

Je souhaiterai que par macro, le remplissage des cellules vides de la colonne B se fasse automatiquement (résultat dans la feuille "Souhait").

Merci d'avance.

Bonjour

Ok mais si la valeur de B2 est vide, on fait quoi ?

sinon code à essayer

Sub test()
Dim i As Integer
Dim valeur
valeur = Range("B2")
For i = 2 To 33
    Select Case Range("B" & i)
        Case Is <> "": valeur = Range("B" & i)
        Case Is = "": Range("B" & i) = valeur
    End Select
Next
End Sub

Cordialement

Bonjour,

Un essai

@+

Bonjour,

Un premier exemple.

Cdlt.

Option Explicit

Public Sub DEMO()
Dim wb As Workbook
Dim ws As Worksheet
Dim lastRow As Long
Dim rng As Range

    Application.ScreenUpdating = False
    '-----------------------------------------------------------------------------
    Set wb = ActiveWorkbook
    Set ws = wb.Worksheets("Import")
    '-----------------------------------------------------------------------------
    With ws
        lastRow = .Cells.SpecialCells(xlCellTypeLastCell).Row
        Set rng = .Cells(2, 2).Resize(lastRow - 1).SpecialCells(xlCellTypeBlanks)
        rng.FormulaR1C1 = "=R[-1]C"
        rng.Value = rng.Value
    End With
    '-----------------------------------------------------------------------------
    Set rng = Nothing
    Set ws = Nothing
    Set wb = Nothing

End Sub

Jusqu'à présent, je ne l'ai jamais vu vide ...

Tout d'abord, merci à tous

Jean-Eric, ça n'a pas fonctionné (ça a tout le temps remplacé les cellules vides par "DDD"

Dan, j'avais oublié de préciser que le nombre de ligne était variable ....

Bernard, c'est parfait

Merci encore à vous trois

Re

Merci de ne pas omettre de clôturer le fil.

Cordialement

Bonjour,

Ma proposition fonctionne parfaitement.

Si je ne me trompe pas .

Voir fichier joint.

Bonjour Jean Eric

Effectivement, ca marche sur le fichier joint

J'ai du déconner avec mon adaptation sur fichier réel au boulot

Merci encore à vous tous