Formule

Bonjour, j’ai besoin d’un coup de main avec des formules Excel

Je cherche une formule pour calculer automatiquement :

Pour chaque mois → le nombre de (A,B ,C etc ) qui additionnerais pour chaque lettre le coût total de celle ci, du tableau feuille 1 sur tableau en feuille deux

j'ai mis en pièces jointes le tableau

merci de votre aide

Bonjour,

Pour janvier tu peux utiliser la formule suivante :

=SOMME.SI.ENS('tableau 1'!M10:M31;'tableau 1'!F10:F31;1;'tableau 1'!H10:H31;'tableau 2'!B10)

tu peux la recopier vers le bas

Pour février il n'y a qu'à modifier le chiffre 1 par 2 dans la partie F10:F31;1; puis 3 pour mars, etc.

Bonne journée

Bonjour,

pour compteur le nombre de A , B ou C tu utilise NB.SI ..

pour effectuer la somme d'une colonne tout en testant si une autre colonne à la valeur A , B ou C tu utilise Somme.Si...

Bonjour,

En D10 :

=SOMMEPROD(('tableau 1'!$H$10:$H$31=$B10)*(MOIS('tableau 1'!$E$10:$E$31)=COLONNE(A:A))*'tableau 1'!$M$10:$M$31)

A étendre sur la totalité du tableau.

Cordialement.

Bonsoir, merci a tous d'avoir répondu si vite.

Monsieur MFERRAND votre formule fonctionne correctement il va falloir que je comprenne le sens de cette formule pour essayé de la dupliqué sur d'autre tableau cette formule est top .

Monsieur ouisansdoute j'ai essayé de mon coté de faire mon tableau avec une formule SOMME. SI. ENS mais je croyais que l'on pouvait mettre les lettres (mois) à la place des chiffre donc j'ai jamais réussi . J'ai essayé de faire mon tableau avec ta formule mais il y a un rappel à gauche de la case ou il mette qu'il y a une erreur (je renvois le tableau et si tu pouvais y jetez un œil) car cette formule a l'air assez simple a réalise et pour un néophyte comme moi cela pourrais me faire gagné du temps et éviter que je vous embête tout le temps

Monsieur Pierre-jy je n’ai pas compris la marche à suivre que vous me demander de suivre! ou vous n'avez pas compris ma question? comme j'aime comprendre et que je suis du genre persévèrent si vous voulez m'expliquer ou me faire un exemple je suis preneur

Bonsoir,

Tu peux effectivement utiliser SOMME.SI.ENS pour ton calcul... Les habitués qui utilisaient SOMMEPROD avant l'apparition de SOMME.SI.ENS, continuent de le préférer car offrant toujours plus de possibilités... Mais dans le cas où le résultat attendu est une somme, cela est indifférent, elles jouent le même rôle.

Au-delà des choix de telle ou telle fonction, quand tu tapes une formule dans une colonne ou un tableau, tu commences en général par la première cellule, ici : D10. Mais l'objectif à ne pas perdre de vue dans la rédaction consiste à faire en sorte que la formule tapée puisse se recopier sur tout le tableau et donne dans chaque cellule de D10 à O22 la réponse juste.

Pour cela on dispose du style de référence des cellules, les références absolues ne varient pas à la recopie, les références relatives s'adaptent, et l'on peut évidemment mixer s'il y a lieu ligne relative-colonne absolue ou l'inverse.

Ainsi, si tu mets B10 dans ta formule en D10 qui pointe sur l'imputation "A" sur cette ligne, recopiée en O22, B10 sera devenue M22, ce qui ne pointe plus la bonne valeur pour la ligne 22.

Si tu mets $B$10, en O22 cela restera $B$10, qui pointe sur "A" qui n'est pas non plus la bonne valeur sur la ligne 22.

Mais si tu mets $B10 en D10, recopiée en O22 cela sera devenu $B22, qui pointe sur "Z", la bonne valeur !

La formule en D10 recopiable, s'écrit donc :

=SOMME.SI.ENS('tableau 1'!$M$10:$M$31;'tableau 1'!$F$10:$F$31;COLONNE(A:A);'tableau 1'!$H$10:$H$31;'tableau 2'!$B10)

Outre le cas de $B10 examiné, il est évident que les plages du tableau 1 ne doivent pas varier et sont les mêmes pour toute cellule du tableau, elles doivent donc être en référence absolue.

Reste le cas de COLONNE(A:A) avec lequel je remplace le 1 que tu avais mis. Si tu mets 1 cela restera 1 lors de la recopie sur toutes les colonnes du tableau, alors COLONNE(A:A) qui renvoie la valeur 1, recopiée sur la colonne voisine à droite deviendra COLONNE(B:B) qui renvoie 2 (comme on le souhaite) et en colonne O sera devenu COLONNE(L:L) renvoyant 12. Ce qui est bien pratique pour avoir une série qui s'incrémente en colonnes.

(Pour incrémenter de la même façon en lignes, on utilise la fonction LIGNE...)

Je te la remets en mode L1C1 si tu préféres continuer à travailler ainsi :

=SOMME.SI.ENS('tableau 1'!L10C13:L31C13;'tableau 1'!L10C6:L31C6;COLONNE(C(-3));'tableau 1'!L10C8:L31C8;'tableau 2'!LC2)

Cordialement.

bonsoir et merci pour toute les explications elle me sont très utile

c'est vrai que j'ai pas encore assimilé la logique excel et comme je pratique un tableau tous les 3 mois en moyenne j'ai tendance a oublier les basses

sinon si je comprend bien sommeprod à débuté avant somme si ens , mais avec sommeprod on a beaucoup plus de possibilité on dirais ?

je reviendrais peu être vers toi car j'ai deux tableau important a faire . mais avant je vais passer des heures à galérer pour comprendre.

Une question, souvent dans les tableaux que je fais nous somme deux a travailler dessus et nous n’écrivons pas pareil ( majuscule ou pas etc) et quand je fais un somme si cela me pose des problèmes il n'y a pas une astuce pour que excel comprenne les deux manière d’écrire ?

merci pour toute les explications que tu m'a apporté

cordialement Eric

Bonsoir,

Ça ! Pour ce qui est de l'esthétique de la présentation, il n'y a pas d'autre solution que modifier... Si tu dois traiter avec une formule, tu disposes de quelques fonctions pour mettre en majuscules ou minuscules ou la première lettre des mots en majsucule (NOMPROPRE).

Pour ce qui est des comparaisons de texte, pas trop de soucis de ce point de vue, par défaut Excel fait ses comparaisons en mode texte et ne distingue pas majuscules et minuscules, et la plupart des fonctions agiront de la même façon. Il n'y en qu'une qui les différencie (sur les deux fonctions de recherche de chaîne de texte) : TROUVE (alors que CHERCHE n'en tient pas compte).

Attention toutefois si tu en viens à travailler en VBA. VBA fait par défaut les comparaisons de texte en mode binaire, et donc différencie majuscules et minuscules. (Pour pallier aux aléas que cela peut provoquer on fait souvent des comparaisons en VBA en mettant les deux termes comparés en majuscules.)

Cordialement.

merci et a bientôt

cordialement