Vérifier si valeur d'une cellule correspond à une liste

Bonjour,

Je souhaite vérifier pour chaque cellule dans une boucle si la valeur de la cellule i colonne 35 correspond à une des valeurs présente dans une liste inscrite dans une autre sheet "PLAGE" en l'occurence 8) .

Si la valeur match alors on inscrit un "FEEDER" dans une colonne sinon on inscrit autre critére "TRADE_MED".

Voila mon code.

Mais je comprends pas si je teste bien la cellule i avec les valeurs de la sheet "PLAGE" ?

Sub rule_number_5()

    Dim ws As Worksheet
    Dim wsc As Worksheet
    Dim DerLigne As Long
    Dim i As Long
    Dim PlageDeRecherche As Range
    Dim trouve As Range

    Set ws = Sheets("Sheet1")
    Set wsc = Sheets("Plage")
    Set PlageDeRecherche = wsc.Columns(1)
    Set Valeur_Cherchee = ws.Columns(i, 35)
    Set trouve = PlageDeRecherche.Cells.Find(what:=Valeur_Cherchee, LookIn:=xlFormulas, LookAt:=xlWhole)
    ws.Activate

'compteur nombre de ligne
    DerLigne = ws.Cells(65536, 3).End(xlUp).Row

    For i = 15 To DerLigne

    If trouve Is Nothing Then
        Cells(i, 36).Value = "FEEDER"

    Else
        Cells(i, 36).Value = "TRADE_MED"
    End If

    Next

    Set PlageDeRecherche = Nothing
    Set trouve = Nothing

End Sub

Merci d'avance de votre aide.

Bonjour,

Sub rule_number_5()
    Dim ws As Worksheet
    Dim DerLigne As Long
    Dim i As Long
    Dim PlageDeRecherche As Range
    Dim trouve As Range
    Dim Valeur_Cherchee

    Set ws = Sheets("Sheet1")
    Set PlageDeRecherche = Sheets("Plage").Columns(1)
'compteur nombre de ligne
    DerLigne = ws.Cells(65536, 3).End(xlUp).Row
    For i = 15 To DerLigne
        Valeur_Cherchee = ws.Columns(i, 35)
        Set trouve = PlageDeRecherche.Cells.Find(what:=Valeur_Cherchee, LookIn:=xlFormulas, _
         LookAt:=xlWhole)
        If trouve Is Nothing Then
            ws.Cells(i, 36).Value = "FEEDER"
        Else
            ws.Cells(i, 36).Value = "TRADE_MED"
        End If
    Next i
End Sub

Cordialement.

NB- Sauf qu'il me semble que tu as inversé les valeurs à porter par rapport à ta déclaration d'intention...

Bonjour MFerrand,

Merci bien pour cette correction en revanche j'ai un message d'erreur définie par l'application ou par l'objet 1004.

Sub rule_number_5()
    Dim ws As Worksheet
    Dim DerLigne As Long
    Dim i As Long
    Dim PlageDeRecherche As Range
    Dim trouve As Range
    'determiné comme string
    Dim Valeur_Cherchee As String

    Set ws = Sheets("Sheet1")
    Set PlageDeRecherche = Sheets("Plage").Columns(1)
'compteur nombre de ligne
   DerLigne = ws.Cells(65536, 3).End(xlUp).Row
    For i = 15 To DerLigne
'erreur définie par l'application ou par l'objet 1004 sur la ligne d'en dessous
        Valeur_Cherchee = ws.Columns(i, 35)
        Set trouve = PlageDeRecherche.Cells.Find(what:=Valeur_Cherchee, LookIn:=xlFormulas, _
         LookAt:=xlWhole)
        If trouve Is Nothing Then
            ws.Cells(i, 36).Value = "FEEDER"
        Else
            ws.Cells(i, 36).Value = "TRADE_MED"
        End If
    Next i
End Sub

bonjour,

remplace

 Valeur_Cherchee = ws.Columns(i, 35)

par

 Valeur_Cherchee = ws.Cells(i, 35)

Salut h2so4,

Je suis bête en effet c'est mieux avec cells.

Merci de ton aide, ça marche mieux comme ça .

Bonne aprés_midi.

En effet ! Je l'avais loupé...

Bonne continuation.

Rechercher des sujets similaires à "verifier valeur correspond liste"