ShowAllData

Bonjour,

Je souhaite supprimer tous les filtres tout en gardant le filtre automatique, mais je n'arrive pas à transcrire cette macro pour un tableau, la cde ShowAllData ne fonctionne pas.

Sub Raz_Filtre1()

'

' Raz_Filtre1 Macro

If ActiveSheet.ListObjects("Tableau1").ShowAutoFilter = True Then

On Error Resume Next

ActiveSheet.ListObjects("Tableau1").ShowAllData

On Error GoTo 0

End If

End Sub

Pilougne

Bonjour,

Essaie ainsi :

Sub Raz_Filtre1()
'
' Raz_Filtre1 Macro
    If ActiveSheet.ListObjects("Tableau1").ShowAutoFilter = True Then
        ActiveSheet.ListObjects("Tableau1").AutoFilter.ShowAllData
    Else
        ActiveSheet.ListObjects("Tableau1").ShowAutoFilter = True
    End If

End Sub

Bonjour Jean-Eric,

Merci avec ton code ça fonctionne, mais j'ai encore un problème si tu peux m'aider:

J’ai un bouton via lequel je détecte si une filtre est activé mais quand je filtre via une date j’ai une erreur 1004 alors que ça fonctionne bien sur les autres colonnes.

Peut-être un problème de longueur ou format ?

Merci encore.

Pilougne

Re,

Ton classeur en retour enregistré au format xlsm.

A te relire.

Cdlt.

Public Sub DEMO4()
'
Dim i As Long
Dim x As String

    Set ws = ActiveSheet
    Set lo = ws.ListObjects(1)

    If lo.ShowAutoFilter Then
        If lo.AutoFilter.FilterMode Then
            For i = 1 To lo.ListColumns.Count
                If lo.AutoFilter.Filters(i).On Then
                    x = lo.HeaderRowRange(i).Value
                    MsgBox "La colonne " & i & " (champ " & x & ") est filtrée." _
                           , vbInformation, "Information"
                End If
            Next i
        End If
    End If

    Set lo = Nothing: Set ws = Nothing

End Sub

Public Sub DEMO5()
'
Set ws = ActiveSheet
Set lo = ws.ListObjects(1)

    If lo.ShowAutoFilter Then
        If lo.AutoFilter.FilterMode Then lo.AutoFilter.ShowAllData
    Else
        lo.ShowAutoFilter = True
    End If

    Set lo = Nothing: Set ws = Nothing

End Sub

Bonjour Jean-Eric,

Merci pour ton code qui fonctionne très bien.

Je te remercie encore et bon dimanche.

Pilougne