Formule de regroupement

Bonjour,

je recherche une solution pour regrouper des valeurs suivant leurs références automatiquement.

L'exemple joint ne contient que 4 références différentes, mais il est possible qu'il en contienne plusieurs 100aine.

Je vous remercie de votre aide.

Bonjour,

J'ai ajouté une fonction tri sur ta colonne regroupement, en cochant ou décochant les valeurs tu peux garder uniquement AA par exemple. Cela te conviendrait-il ?

Merci, j'ai l'habitude de travailler comme ça, mais comme mes fichiers peuvent contenir plusieurs centaines de références, je ne voudrais pas passer tout mon temps à faire le tri.

J'avais déjà trouvé une macro pour regrouper les cellules automatiquement dans une seule (comme dans le 2e tableau, colonne valeur), mais les valeurs n'étaient pas regroupées par référence.

Y aurait-il une solution en macro?

Bonsoir Martin1972, Girodo, le forum

A tester, restitution à côté du tableau initial.

Option Explicit
Sub test()
Dim a, i As Long, j As Long, n As Long
    With Sheets("Feuil1").Range("a1").CurrentRegion
        a = .Value
        With CreateObject("Scripting.Dictionary")
            .CompareMOde = 1
            For i = 2 To UBound(a, 1)
                If Not .exists(a(i, 1)) Then
                    n = n + 1: .Item(a(i, 1)) = n
                    For j = 1 To 2
                        a(n, j) = a(i, j)
                    Next
                Else
                    a(.Item(a(i, 1)), 2) = a(.Item(a(i, 1)), 2) & "," & a(i, 2)
                End If
            Next
        End With
        With .Offset(, .Columns.Count + 3)
            .CurrentRegion.Clear
            .Resize(1, 2).Value = Array("REFERENCE", "VALEUR")
            .Offset(1).Resize(n).Value = a
            With .CurrentRegion
                .Rows(1).BorderAround Weight:=xlThin
                .BorderAround Weight:=xlThin
                .Borders(xlInsideVertical).Weight = xlThin
            End With
        End With
    End With
End Sub

klin89

Je viens d'essayer en rajoutant 2 références et valeurs et ça marche impeccable!

J'essaierais demain avec mon gros fichier et je confirmerais ça mais je penses que c'est sur la bonne voie!

Merci

Bonjour Klin89 et merci pour cette macro, elle rempli parfaitement la fonction que je voulais.

J'ai pu la tester avec des fichiers de 1500 lignes, et les valeurs sont classées directement.

Merci encore!