[VBA] probleme enregistrer-sous en .pdf

Bonsoir,

Comme le nom du sujet l' indique je bloque sur l' insertion de ce code dans ma macro pour pouvoir sauvegarder mon fichier en .PDF.

Code :

ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _, Quality:= _
    xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, _

Ma macro :

Private Sub CommandButton1_Click()
  Application.DisplayAlerts = False
  Dim Chemin As String, Fichier As String, Rep As String
  Chemin = "D:\SARL\Devis\"
  Rep = Application.Proper(MonthName(Month(Date))) & " " & Year(Date)
  On Error Resume Next
  MkDir Chemin & Rep
  On Error GoTo 0
  Chemin = Chemin & Rep & "\"
  Sheets("Devis").Copy
  Fichier = Sheets("Devis").Range("C4") & " " & "F" & Format(Date, "ddmmyyyy") & ".xlsx"
  With ActiveWorkbook
    .SaveAs Filename:=Chemin & Fichier
    .Close
    Application.DisplayAlerts = True
    MsgBox ("Enregistré dans le dossier -Devis-")
  End With
End Sub

J'ai lu plusieurs post sur le sujet mais tout mes essais ont aboutis a des erreurs.

Une âme charitable pourrait-elle me venir en aide ?

Cordialement.

Bonjour

A tester

Private Sub CommandButton1_Click()
  Application.DisplayAlerts = False
  Dim Chemin As String, Fichier As String, Rep As String
  'Chemin = "D:\SARL\Factures\"
  Chemin = ThisWorkbook.Path & "\"
  Rep = Application.Proper(MonthName(Month(Date))) & " " & Year(Date)
  On Error Resume Next
  MkDir Chemin & Rep
  On Error GoTo 0
  Chemin = Chemin & Rep & "\"
  Sheets("Factures").Copy
  Fichier = Sheets("Factures").Range("C4") & " " & "F" & Format(Date, "ddmmyyyy") & ".Pdf"
  With ActiveWorkbook
    .ExportAsFixedFormat Type:=xlTypePDF, Filename:=Chemin & Fichier, Quality:=xlQualityStandard, _
                          IncludeDocProperties:=True, IgnorePrintAreas:=False, _
                          From:=1, To:=1, OpenAfterPublish:=False
    '.SaveAs Filename:=Chemin & Fichier
    .Close savechanges:=False
    Application.DisplayAlerts = True
    MsgBox ("Enregistré dans le dossier -Factures-")
  End With
End Sub

Bonsoir bonzaï et merci de me répondre

le code fonctionne partiellement, il enregistre bien le fichier en pdf mais le dossier " décembre 2015" ce trouve dans "SARL" et non dans "Factures".

J'avoue ne pas bien comprendre le fonctionnement de ce code. Il me semble avoir essayé cette procédure mais mon fichier était illisible par mon lecteur pdf alors que là il l'est

a te lire

Bonjour,

as tu essayé de changer la ligne

Chemin = ThisWorkbook.Path & "\"

par

Chemin = "D:\SARL\Factures\"

bonsoir Patrick,

Effectivement cela fonctionne, la solution était pourtant évidente.

Un grand merci a toi et Banzaï, grâce a vous mon projet avance considérablement.

Encore merci a vous deux et bon week-end