Charger Listbox uniquement avec date dépassé

Bonjour,

J’ai un petit souci pour une listbox,

En effet j’ai un fichier Excel avec une colonne « date de fin » et j’aimerai que la listbox ne charge uniquement que les ligne qui sont avec des date dépassés par rapport à la date du jour

Voici le code que j’ai qui fonctionne presque mais sauf qu’il me charge toutes les lignes.

Private Sub UserForm_initialize()
Dim L As Integer
Dim i As Integer
On Error Resume Next
UserForm8.ListBox2.Clear
  Me.ListBox2.ColumnCount = 3
  Me.ListBox2.ColumnWidths = "40,70,50"
  Me.ListBox2.RowSource = "A2:C" & [C65000].End(xlUp).Row

    Dim la_date As Date
la_date = Sheets("Feuil1").Range("b" & i)
If la_date < Now Then
    With ListBox2
.AddItem Sheets("Feuil1").Range("a" & i).Row
     End With
        With Sheets("Feuil1")
           L = .Range("B65536").End(xlUp).Row
      End With
End If
  For i = 2 To L
Next i
End Sub

Merci pour votre soutien

Bonjour,

Essaie comme cela

Private Sub UserForm_initialize()
Dim i As Long, DerLig As Long
    On Error Resume Next
    Me.ListBox2.ColumnCount = 3
    Me.ListBox2.ColumnWidths = "40,70,50"
    With Sheets("Feuil1")
        DerLig = .Range("C" & Rows.Count).End(xlUp).Row
        For i = 2 To DerLig
            If .Range("B" & i).Value < Date Then
                Me.ListBox2.AddItem .Range("A" & i).Value
                Me.ListBox2.List(Me.ListBox2.ListCount - 1, 1) = .Range("B" & i).Value
                Me.ListBox2.List(Me.ListBox2.ListCount - 1, 2) = .Range("C" & i).Value
            End If
        Next i
    End With
End Sub

A+

Merci Beaucoup !

ça marche a la perfection !!