Calcul de la somme des cellules
Bonjour,
dans une ligne ou colonne, plusieurs chiffres (6) sont entrés, je souhaiterais faire la somme des 4 plus petits.
Avez vous une formule de calcul
Merci d'avance
Bonjour et bienvenu sur le forum,
Essaye l'une des formules suivantes, PLAGE étant la ligne ou la colonne à sommer :
=SOMME(PETITE.VALEUR(PLAGE;1);PETITE.VALEUR(PLAGE;2);PETITE.VALEUR(PLAGE;3);PETITE.VALEUR(PLAGE;4))=PETITE.VALEUR(PLAGE;1)+PETITE.VALEUR(PLAGE;2)+PETITE.VALEUR(PLAGE;3)+PETITE.VALEUR(PLAGE;4)Bonjour et bienvenue,
Une formule inspirée d'un des derniers posts de Thibo.
Avec tes chiffres de A1 à A6
=SOMMEPROD((A1:A6<=PETITE.VALEUR(A1:A6;4))*A1:A6)edit : problème si doublons
Sylvain TBM a écrit :Bonjour et bienvenue,
Une formule inspirée d'un des derniers posts de Thibo.
Avec tes chiffres de A1 à A6
=SOMMEPROD((A1:A6<=PETITE.VALEUR(A1:A6;4))*A1:A6)edit : problème si doublons
Merci beaucoup à vous
Re, Salut Sylvain,
Formule inspirée par celle qui proposée par Sylvain :
=SOMME.SI(PLAGE;"<="&PETITE.VALEUR(PLAGE;4))Re, salut Raja, on se croise aujourd'hui...
Attention, comme je te le disais plus haut, tu auras des problèmes si ta petite.valeur(plage;4) est présente plusieurs fois.
Ex :
1
2
3
4
4
5
Tu vas avoir comme somme 1+2+3+4+4=14
Salut le forum
Voici la formule miracle, la somme des 4 plus petites valeurs, mêmes avec doublons.
=SOMME(PETITE.VALEUR(A1:A6;{1;2;3;4}))Mytå
Voici un tableau et je dois faire la somme de la ligne "points" que de 4 cellules, sachant quelles ont une formule de calcul. La formule ci dessus fonctionne bien si les chiffres se suivent, mais pas dans le cas du tableau.
Merci d'avance
https://www.excel-pratique.com/~files/doc/resultat_final.xls
Salut le forum
Criquet, c'est plus les mêmes conditions, une colonne sur deux
Formule fonctionnelle que sous Excel 2007 (A valider par Ctrl + Shift + Enter)
A mettre en R6 pour comparer les résultats, et à recopier ensuite vers le bas.
=SOMME(GRANDE.VALEUR(EST.IMPAIR(COLONNE($D6:$O6))*($D6:$O6);{3;4;5;6}))ou
=SOMME(PETITE.VALEUR(EST.IMPAIR(COLONNE($D6:$O6))*($D6:$O6);{7;8;9;10}))Il ne doit pas avoir de vide dans tes points (Inscrit 999 au besoin)
Sinon une formule Si qui vérifierait le nombre de valeurs dans la lignes pour
adapter le {3;4;5;6} ou le {7;8;9;10}
Mytå
Mytå a écrit :Salut le forum
Criquet, c'est plus les mêmes conditions, une colonne sur deux
Formule fonctionnelle que sous Excel 2007 (A valider par Ctrl + Shift + Enter)
A mettre en R6 pour comparer les résultats, et à recopier ensuite vers le bas.
=SOMME(GRANDE.VALEUR(EST.IMPAIR(COLONNE($D6:$O6))*($D6:$O6);{3;4;5;6}))ou
=SOMME(PETITE.VALEUR(EST.IMPAIR(COLONNE($D6:$O6))*($D6:$O6);{7;8;9;10}))Il ne doit pas avoir de vide dans tes points (Inscrit 999 au besoin)
Sinon une formule Si qui vérifierait le nombre de valeurs dans la lignes pour
adapter le {3;4;5;6} ou le {7;8;9;10}
Bonjour à tous
Je reviens sur ma demande, car je me suis mal exprimé, il me semble.
Sur le tableau ci-joint, je souhaite faire la somme, dans la case en jaune, des 4 plus petits nombres des cellules E6, G6, I6, K6,M6, O6.
Merci d'avance
Criquet
https://www.excel-pratique.com/~files/doc/resultat_final_essai.xls[/quote]
Bonjour,
à essayer :
=SOMME(PETITE.VALEUR(SI(MOD(COLONNE($E$6:$O$6);2)=1;($E$6:$O$6)*MOD(COLONNE($E$6:$O$6);2));{1;2;3;4}))Formule matricielle à valider par CTRL + MAJ + ENTREE
@+
Bonjour
Toujours en Matricielles à valider par CTRL + MAJ + ENTREE
Fonctionne aussi avec Excel antérieur à 2007
=SOMME(PETITE.VALEUR(MOD(COLONNE($E6:$O6);2)*($E6:$O6);{6;7;8;9}))ou
=SOMMEPROD(PETITE.VALEUR((MOD(COLONNE($E6:$O6);2)*($E6:$O6));LIGNE(INDIRECT("6:9"))))ou
=SOMMEPROD(PETITE.VALEUR((MOD(COLONNE($E6:$O6);2)*($E6:$O6));{6;7;8;9}))Cordialement
Bonjour
Et pour compléter la remarque de Myta, une adaptation pour ajuster automatiquement les valeurs sans avoir à rechercher leur position.
=SOMMEPROD(PETITE.VALEUR((MOD(COLONNE($E6:$O6);2)*($E6:$O6));LIGNE(INDIRECT((COLONNES($E6:$O6)+1)/2&":"&((COLONNES($E6:$O6)+1)/2)+3))))Détails sur le fichier
https://www.excel-pratique.com/~files/doc/tGm6Qresultat_final_essai.xls
Cordialement