Supprimer les cellules vides d'une colonne déclarée

Bonjour à tous,

J'ai ce code ici,

Sheets("123").Select
Dim dernligne As Double
dernligne = Worksheets("123").Range("B65536").End(xlUp).Row + 1
Rows(dernligne).Select
Range(Selection, Selection.End(xlDown)).Select
Selection.Delete Shift:=xlUp

qui me permet de supprimer toutes les lignes vides en dessous de mon tableau (Problème dans un autre soft qui me trouve les lignes vides en dessous comme pleines et qui plante)

J'aimerais adapter ceci pour que cela ne se fasse pas en colonne B mais dans une autre colonne qui peut cependant changer suivant le tableau. Du coup cette colonne a un nom, à savoir: "colonne"

Comment puis-je effectuer cette opération dans colonne, sachant que colonne peut se trouver colonne BA ou BD ou n'importe où à vrai dire ><.

Merci par avance et bonne journée à vous.

Bonjour Captainmikou, bonjour le forum,

Pas sûr d'avoir bien compris. Peut-être comme ça :

Sub Macro1()
Dim O As Worksheet 'déclare la variable O (Onglet)
Dim R As Range 'déclare la variable R (Recherche)
Dim COL As Integer 'déclare la variable COL (COLonne)
Dim PLV As Integer 'déclare la variable PLV (Premiere Ligne Vide)

Set O = Sheets("123") 'définit l'onglet O
Set R = O.Rows(1).Find("colonne", , xlValues, xlWhole) 'définit la recherche R (recherche le mot "colonne" dans la ligne 1) à adapter
If Not R Is Nothing Then 'condition : si il existe au moins une occurrence trouvée
    COL = R.Column 'définit la colonne COL
Else 'sinon
    MsgBox "Colonne inexistante ! La suppression des lignes vide ne peux se faire." 'message
    Exit Sub 'sort de la procédure
End If 'fin de la condition
PLV = O.Cells(Application.Rows.Count, COL).End(xlUp).Row + 1 'définit la première ligne vide PLV de la colonne COL
O.Range(O.Cells(PLV, COL), O.Cells(Application.Rows.Count, COL)).Delete 'efface toutes les cellules de PLV à la dernière de la colonne COL
End Sub

Bonjour,

Merci bien pour votre réponse, ca marche !

Bonne journée à vous