Login et mot de passe

Bonjour,

Alors je vous expliques une fonction que j'aimerais mettre en place dans un de mes fichier excel et cela à travers un Userform

- J'ai une feuille excel qui regroupe plusieurs utilisateurs avec comme mot de passe définie par eux même

1) toto ==> 123

2) tata ==> 456

3) titi ==> 789

J'ai utiliser dans un module :

Function VerifMDP(Utilisateur As String, Mdp As String) As Boolean
    Dim rngTrouve As Range
    VerifMDP = False
    With Sheets("Utilisateur")
        Set rngTrouve = .Columns(1).Cells.Find(Utilisateur, lookat:=xlWhole)
            If rngTrouve Is Nothing Then
                VerifMDP = False
            Else
                If rngTrouve.Offset(0, 5) <> Mdp Then
                    VerifMDP = False
                Else
                    VerifMDP = True
                End If
            End If
    End With
End Function

et sur mon bouton valider :

Private Sub CommandButton6_Click()

    If TextBox3 = "" Then
        MsgBox "Saisie du nom d'utilisateur obligatoire."
    End If

    If TextBox2 = "" Then
        MsgBox "Saisie du Mot de passe obligatoire."
    End If

    If VerifMDP.VerifMDP(TextBox3, TextBox2) = False Then
        MsgBox " Erreur Mot de passe et/ou utilisateur Merci de saisir à nouveau."
        TextBox2 = ""
        TextBox3 = ""
    End If
'VerifMDP.AfficheFeuilles TextBox3
UserForm5.Hide
UserForm1.Show
End Sub

Et en conclusion à chaque fois que je fais valider ( je rentre dans l'userform5 ) et en plus j'ai un message d'erreur me disant Erreur Mot de passe et/ou utilisateur Merci de saisir à nouveau. ( alors que je rentre avec un bon utilisateur et un mot de passe ou même si je met pas de mot de passe juste un utilisateur )

Si une personne peu m’éclairer sur mon erreur j'en serais vraiment reconnaissant car la je bloque depuis plusieurs heures et j'aimerais pouvoir clôturer ce module pour mon logiciel

Bonjour,

Supprime la partie surlignée pour commencer (doublon).

 If VerifMDP.VerifMDP(TextBox3, TextBox2) = False Then

Jean-Eric a écrit :

Bonjour,

Supprime la partie surlignée pour commencer (doublon).

 If VerifMDP.VerifMDP(TextBox3, TextBox2) = False Then

alors j'avais tester justement de l'enlever mais cela avais mis une erreur :

"Erreur de compilation :

Variable ou procédure attendue, et non un module "

et comme je fait appel à mon module VerifMDP et à la fonction VerifMDP dans celui-ci j'avais mis cela pour qu'il puisse l'interprété

Erreur trouver j'avais pas mis les Exit Sub ...

voici le script dans mon module :

Option Explicit

Function VerifMDP(Utilisateur As String, MdP As String) As Boolean
Dim rngTrouve As Range
VerifMDP = False

With Sheets("Utilisateur")
    Set rngTrouve = .Columns(1).Cells.Find(Utilisateur, lookat:=xlWhole)
    If rngTrouve Is Nothing Then
    Else
        If rngTrouve.Offset(0, 1) <> MdP Then
            VerifMDP = False
        Else
            VerifMDP = True
        End If
    End If
End With
End Function

Sub AfficheFeuilles(Utilisateur As String)
Dim Col As Byte, i As Byte, Lig As Integer

With Sheets("Utilisateur")
    Col = .Cells(1, .Cells.Columns.Count).End(xlToLeft).Column
    Lig = .Columns(1).Cells.Find(Utilisateur, lookat:=xlWhole).Row

    For i = 3 To Col
        If UCase(.Cells(Lig, i)) = "X" Then
            Sheets(.Cells(1, i).Value).Visible = True
        Else
            Sheets(.Cells(1, i).Value).Visible = xlSheetVeryHidden
        End If
    Next i
End With
End Sub

et le script sur mon bouton :

Private Sub CommandButton6_Click()

If TextBox3 = "" Then
    MsgBox "Saisie du nom d'utilisateur obligatoire.", vbInformation
Exit Sub
End If

If TextBox2 = "" Then
    MsgBox "Saisie du mot de passe obligatoire.", vbInformation
Exit Sub
End If

If VerifMDP.VerifMDP(TextBox3, TextBox2) = False Then
    MsgBox "Erreur Mot de passe et/ou utilisateur. Merci de saisir à nouveau.", vbInformation
    TextBox3 = ""
    TextBox2 = ""
    Exit Sub
End If
'AfficheFeuilles TextBox3
UserForm5.Hide
UserForm1.Show
End Sub